From 25f760889066017e85b157e8f55158dc6394e95e Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sun, 4 Oct 2020 19:01:01 +0000
Subject: libfido2: 1.5.0

---
 abs/extra/libfido2/PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 abs/extra/libfido2/PKGBUILD

diff --git a/abs/extra/libfido2/PKGBUILD b/abs/extra/libfido2/PKGBUILD
new file mode 100644
index 0000000..9e2d5e2
--- /dev/null
+++ b/abs/extra/libfido2/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Karol Babioch <karol@babioch.de>
+
+pkgname=libfido2
+pkgver=1.5.0
+pkgrel=2
+pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
+url='https://developers.yubico.com/libfido2/'
+arch=('x86_64')
+license=('BSD')
+depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so')
+makedepends=('cmake' 'systemd')
+provides=('libfido2.so')
+source=(https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz{,.sig})
+sha512sums=('240e2368e43846fddf5e98bbcc247468833565bcde4ec27976b88c814d787f1a477241a82b064818aa0eb0a98ff46a65d80b8243f4d0bbd763270e42492354e2'
+            'SKIP')
+b2sums=('23a04f9230c45652aa1ac9fd8b3e809096ae31699c65ca0fda27b27b1b47263e375bb99e5b1ebc515b9edfb801bb2fba9c4f50d88e755efe3eaa23463ca01946'
+        'SKIP')
+validpgpkeys=(
+  'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro@yubico.com>
+  '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail@yubico.com>
+  '7FBB6186957496D58C751AC20E777DD85755AA4A' # Konstantinos Georgantas <kostas@yubico.com>
+)
+
+build() {
+  cd ${pkgname}-${pkgver}
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}"
+  make -C build VERBOSE=1
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:
-- 
cgit v0.12

