From 5bfe04bf2ad9c0e991797d956f3b34c153756688 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Mar 2018 18:36:55 +0000
Subject: python-pluggy: dep of python-pytest

---
 abs/core/python_modules/python-pluggy/PKGBUILD | 53 ++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 abs/core/python_modules/python-pluggy/PKGBUILD

diff --git a/abs/core/python_modules/python-pluggy/PKGBUILD b/abs/core/python_modules/python-pluggy/PKGBUILD
new file mode 100644
index 0000000..8f304a4
--- /dev/null
+++ b/abs/core/python_modules/python-pluggy/PKGBUILD
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+pkgbase=python-pluggy
+pkgname=(python-pluggy python2-pluggy)
+pkgver=0.6.0
+pkgrel=2
+pkgdesc="Plugin and hook calling mechanisms for python"
+arch=('any')
+url="https://www.pluggypayments.com/docs/python"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/pytest-dev/pluggy/archive/$pkgver.tar.gz")
+sha512sums=('ed8fe81907c7dc476ebfbf0f7e0f902577323d64014765e7d7bfe22c2dc7e4977e1ce7ad55ce7f4e923ae23d206d6c3bcc6663de760c877fce82298cc21079db')
+
+prepare() {
+  cp -a pluggy-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/pluggy-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/pluggy-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/pluggy-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/pluggy-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-pluggy() {
+  depends=('python')
+
+  cd pluggy-$pkgver
+  python setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pluggy() {
+  depends=('python2')
+
+  cd pluggy-$pkgver-py2
+  python2 setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
-- 
cgit v0.12

