From 88360caae91ebbd31332cd86992c5ff849e1a179 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 21 Feb 2019 02:08:06 +0000
Subject: eglexternalplatform: dep of egl-wayland

---
 abs/extra/eglexternalplatform/PKGBUILD | 33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 abs/extra/eglexternalplatform/PKGBUILD

diff --git a/abs/extra/eglexternalplatform/PKGBUILD b/abs/extra/eglexternalplatform/PKGBUILD
new file mode 100644
index 0000000..c163baa
--- /dev/null
+++ b/abs/extra/eglexternalplatform/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+
+pkgname=eglexternalplatform
+pkgver=1.0+3+g7c8f8e2
+pkgrel=1
+pkgdesc="EGL External Platform interface"
+url=https://github.com/NVIDIA/eglexternalplatform
+arch=(any)
+license=(MIT)
+depends=(mesa)
+makedepends=(git)
+_commit=7c8f8e2218e46b1a4aa9538520919747f1184d86  # master
+source=("git+$url#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git tag -f 1.0 53bf47ccd349b7525248687ba0058860168c8580  # Fixup missing tag
+}
+
+package() {
+  cd $pkgname
+  install -Dt "$pkgdir/usr/include/EGL" -m644 interface/*
+  install -Dt "$pkgdir/usr/share/pkgconfig" -m644 *.pc
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}
+
+# vim:set sw=2 et:
-- 
cgit v0.12

