From ef1ddf53debb4c64aed0fa63b4382e9ec33ef3e4 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 21 Feb 2019 14:14:25 +0000
Subject: bubblewrap. dep of opam

---
 abs/extra/bubblewrap/PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 abs/extra/bubblewrap/PKGBUILD

diff --git a/abs/extra/bubblewrap/PKGBUILD b/abs/extra/bubblewrap/PKGBUILD
new file mode 100644
index 0000000..5d443dd
--- /dev/null
+++ b/abs/extra/bubblewrap/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
+
+pkgname=bubblewrap
+pkgver=0.3.1
+pkgrel=1
+pkgdesc='Unprivileged sandboxing tool'
+url='https://github.com/projectatomic/bubblewrap'
+arch=(x86_64)
+license=(GPL)
+depends=(glibc libcap)
+makedepends=(libxslt docbook-xsl git)
+_commit=e7b517f40956a153972fd61a2c6da1140f52990b  # tags/v0.3.1^0
+source=(git+$url#commit=$_commit)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe | sed 's/^v//'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+    --with-priv-mode=setuid
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}
-- 
cgit v0.12

