From f7821feafe58f904fbf83c2f86710ede24641495 Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Mon, 6 Aug 2012 21:33:52 -0500
Subject: idnkit 1.0 -new

---
 abs/core/idnkit/PKGBUILD | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 abs/core/idnkit/PKGBUILD

diff --git a/abs/core/idnkit/PKGBUILD b/abs/core/idnkit/PKGBUILD
new file mode 100644
index 0000000..2a5fd25
--- /dev/null
+++ b/abs/core/idnkit/PKGBUILD
@@ -0,0 +1,40 @@
+# $Id: PKGBUILD 142702 2011-11-13 10:10:08Z bisson $
+# Contributor: Igor Nemilentsev <trezorg@gmail.com>
+# Maintainer: Gaetan Bisson <bisson@archlinux.org>
+
+pkgname=idnkit
+pkgver=1.0
+pkgrel=2
+pkgdesc='Provides functionalities about Internationalized Domain Name processing'
+url='http://www.nic.ad.jp/ja/idn/idnkit/download/'
+license=('custom:BSD')
+arch=('i686' 'x86_64')
+depends=('glibc')
+options=('!makeflags' '!libtool')
+source=("http://www.nic.ad.jp/ja/idn/idnkit/download/sources/idnkit-${pkgver}-src.tar.gz")
+sha1sums=('7d843ffcf9843b7af02079e5a160520f28c75048')
+
+backup=('etc/idnalias.conf' 'etc/idn.conf')
+
+build() {
+	cd "${srcdir}/idnkit-${pkgver}-src"
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--localstatedir=/var \
+		--mandir=/usr/share/man \
+		--enable-static=no
+	make
+}
+
+check() {
+	cd "${srcdir}/idnkit-${pkgver}-src"
+	make check
+}
+
+package() {
+	cd "${srcdir}/idnkit-${pkgver}-src"
+	make DESTDIR="${pkgdir}" install
+	install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	rm "${pkgdir}"/etc/*.sample
+}
-- 
cgit v0.12

