From 20a340f6fc367f8c139c0baba712de8d522dbab5 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sun, 9 Jun 2019 17:14:54 +0000
Subject: python-requests-toolbelt: initial inclusion, dep of python-acme

---
 .../python-requests-toolbelt/PKGBUILD              | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 abs/core/python_modules/python-requests-toolbelt/PKGBUILD

diff --git a/abs/core/python_modules/python-requests-toolbelt/PKGBUILD b/abs/core/python_modules/python-requests-toolbelt/PKGBUILD
new file mode 100644
index 0000000..ac5f91b
--- /dev/null
+++ b/abs/core/python_modules/python-requests-toolbelt/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: eolianoe <eolianoe At GoogleMAIL DoT com>
+
+pkgbase=python-requests-toolbelt
+pkgname=('python-requests-toolbelt' 'python2-requests-toolbelt')
+pkgver=0.9.1
+pkgrel=1
+pkgdesc="A toolbelt of useful classes and functions to be used with python-requests."
+arch=('any')
+url="https://github.com/requests/toolbelt"
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests')
+checkdepends=('python-pytest' 'python2-pytest' 'python-betamax' 'python2-betamax'
+              'python-mock' 'python2-mock' 'python-pyopenssl' 'python2-pyopenssl')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/requests/toolbelt/archive/$pkgver.tar.gz")
+sha512sums=('12667056c225ce0bc88a5959660103feed23810890abd3890ef15581aa64c09c0552c3974473e1742cbe6200bd37d6475ad34ec051e83d4fbf0a33f320dbc0cc')
+
+prepare() {
+  cp -a toolbelt-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/toolbelt-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/toolbelt-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/toolbelt-$pkgver
+  py.test
+
+  cd "$srcdir"/toolbelt-$pkgver-py2
+  py.test2
+}
+
+package_python-requests-toolbelt() {
+  depends=('python-requests')
+
+  cd toolbelt-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-requests-toolbelt() {
+  depends=('python2-requests')
+
+  cd toolbelt-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
-- 
cgit v0.12