From 563163ffdb168c3768c1b0591e2a39d4fbf8d774 Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Tue, 7 Aug 2012 15:51:56 -0500
Subject: vte3 .32

---
 abs/extra/vte3/PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 abs/extra/vte3/PKGBUILD

diff --git a/abs/extra/vte3/PKGBUILD b/abs/extra/vte3/PKGBUILD
new file mode 100644
index 0000000..1019be3
--- /dev/null
+++ b/abs/extra/vte3/PKGBUILD
@@ -0,0 +1,39 @@
+# $Id: PKGBUILD 160601 2012-06-02 20:33:51Z ibiru $
+# Maintainer: Ionut Biru <ibiru@archlinux.org>
+
+pkgbase=vte3
+pkgname=(vte3 vte-common)
+pkgver=0.32.2
+pkgrel=1
+pkgdesc="Virtual Terminal Emulator widget for use with GTK3"
+arch=('i686' 'x86_64')
+license=('LGPL')
+options=('!libtool' '!emptydirs')
+makedepends=('intltool' 'gobject-introspection' 'gtk3')
+url="http://www.gnome.org"
+source=(http://ftp.gnome.org/pub/GNOME/sources/vte/${pkgver%.*}/vte-$pkgver.tar.xz)
+sha256sums=('d69ec071f7a380d8b8b981b35a9a0b891f37c4b6b17d08407f66ac98d619486a')
+
+build() {
+  cd "vte-$pkgver"
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --libexecdir=/usr/lib/vte \
+      --localstatedir=/var --disable-static \
+      --enable-introspection
+  make
+}
+
+package_vte3(){
+  depends=('gtk3' 'vte-common')
+  cd "vte-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  rm "$pkgdir"/usr/lib/vte/gnome-pty-helper
+}
+
+package_vte-common() {
+  pkgdesc="Common files used by vte and vte3"
+  cd "vte-$pkgver"
+
+  make -C gnome-pty-helper DESTDIR="$pkgdir" install
+}
-- 
cgit v0.12

