From 4d6d7503d83fa595b9396b9b8d0c9f07448f0e33 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 27 Oct 2017 17:31:06 +0000
Subject: ninja: initial inclusion, dep of gyp
---
abs/extra/ninja/PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
create mode 100644 abs/extra/ninja/PKGBUILD
diff --git a/abs/extra/ninja/PKGBUILD b/abs/extra/ninja/PKGBUILD
new file mode 100644
index 0000000..ba37b3f
--- /dev/null
+++ b/abs/extra/ninja/PKGBUILD
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
+# Contributor: Filip Brcic <brcha@gna.org>
+# Contributor: Mika Fischer <mika.fischer@zoopnet.de>
+# Contributor: Gergely Imreh <imrehgATgmailDOTcom>
+
+pkgname=ninja
+pkgver=1.8.2
+pkgrel=1
+pkgdesc='Small build system with a focus on speed'
+arch=(i686 x86_64)
+url='https://ninja-build.org/'
+license=(Apache)
+depends=(gcc-libs)
+makedepends=(python2 re2c emacs)
+source=($pkgname-$pkgver.zip::https://github.com/martine/ninja/archive/v$pkgver.zip)
+sha1sums=('7d252d8deeefd6972080f146a528fad76698616c')
+
+build() {
+ cd ninja-$pkgver
+
+ python2 configure.py --bootstrap
+ emacs -Q --batch -f batch-byte-compile misc/ninja-mode.el
+}
+
+check() {
+ cd ninja-$pkgver
+
+ python2 ./configure.py
+ ./ninja ninja_test
+ ./ninja_test --gtest_filter=-SubprocessTest.SetWithLots
+}
+
+package() {
+ cd ninja-$pkgver
+
+ install -m755 -D ninja "$pkgdir/usr/bin/ninja"
+ install -m644 -D doc/manual.asciidoc "$pkgdir/usr/share/doc/ninja/manual.asciidoc"
+ install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+
+ install -m644 -D misc/ninja-mode.el "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.el"
+ install -m644 -D misc/ninja-mode.elc "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.elc"
+ install -m644 -D misc/ninja.vim "$pkgdir/usr/share/vim/vimfiles/syntax/ninja.vim"
+
+ install -m644 -D misc/bash-completion "$pkgdir/usr/share/bash-completion/completions/ninja"
+ install -m644 -D misc/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_ninja"
+}
--
cgit v0.12