# $Id: PKGBUILD 1939 2008-05-24 00:35:29Z james $
# Maintainer: James Rayner <iphitus@gmail.com>
# Contributor: lydgate

pkgname=mlocate
pkgver=0.20
pkgrel=11
pkgdesc="Faster merging drop-in for slocate"
arch=(i686 x86_64)
url="http://carolina.mff.cuni.cz/~trmac/blog/mlocate"
license=("GPL")
groups=("base")
conflicts=('slocate')
provides=('slocate')
replaces=('slocate')
depends=('glibc')
backup=('etc/updatedb.conf')
install=mlocate.install
source=("https://fedorahosted.org/mlocate/attachment/wiki/MlocateDownloads/mlocate-$pkgver.tar.bz2?format=raw" \
	updatedb.conf updatedb.cron.daily)
build() {
  cd "$startdir"/src/$pkgname-$pkgver

  # Build!
  sed -i '/^groupname /s/mlocate/locate/' Makefile.in
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var/lib
  make || return 1

  # Set up a default updatedb.conf and a daily cronjob
  install -v -D -m644 ../updatedb.conf "$startdir"/pkg/etc/updatedb.conf
  install -v -D -m744 ../updatedb.cron.daily "$startdir"/pkg/etc/cron.daily/updatedb

  # Install Mlocate
  make DESTDIR="$startdir"/pkg install

  cd "$startdir"/pkg
  ln -sv locate usr/bin/slocate
  chgrp -v 21 usr/bin/locate
  chmod -v 2755 usr/bin/locate

  mkdir -pv var/lib
  install -d -m750 -g21 var/lib/locate
}

md5sums=('ad5e4eb1f2aecf1a5af9fe36c6e297f4'
         '08f642828fe8a6a0c8e5059133c9a9e2'
         'eee7f9db8c6145724313af6fd5fe9d66')