# $Id: PKGBUILD 2319 2008-05-31 21:01:41Z eric $
# Maintainer: Judd Vinet <jvinet@zeroflux.org>
pkgname=syslog-ng
_pkgver=2.0.10
pkgver=2.0.9.10
pkgrel=11
pkgdesc="Next-generation syslogd with advanced networking and filtering capabilities"
arch=(i686 x86_64)
license=('GPL')
groups=('base')
url="http://www.balabit.com/network-security/syslog-ng/"
depends=('logrotate' 'glibc')
makedepends=('flex' 'glib2' 'eventlog' 'pkgconfig' 'tcp_wrappers')
provides=('logger')
backup=('etc/syslog-ng.conf' 'etc/logrotate.d/syslog-ng')
source=(http://www.balabit.com/downloads/files/syslog-ng/sources/${_pkgver}/source/${pkgname}_${_pkgver}.tar.gz \
	syslog-ng.conf syslog-ng.logrotate syslog-ng)
md5sums=('e5ca55796c11899739affa417ff8a71e'
         'ee95af3a4f969f3759e477289305c8c6'
         '65d52180f1762e3985168fffa1faf0a8'
         '9bd98250cfa49e13fa3fa731b6040549')

build() {
  cd $startdir/src/$pkgname-${_pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var/lib/syslog-ng --enable-tcp-wrapper \
    --disable-spoof-source
  make || return 1
  make DESTDIR=$startdir/pkg install || return 1
  install -d $startdir/pkg/var/lib/syslog-ng
  install -D -m644 ../syslog-ng.conf $startdir/pkg/etc/syslog-ng.conf
  install -D -m644 ../syslog-ng.logrotate $startdir/pkg/etc/logrotate.d/syslog-ng
  install -D -m755 ../syslog-ng $startdir/pkg/etc/rc.d/syslog-ng
}