# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=fluxbox
pkgver=1.3.1
pkgrel=7
pkgdesc="A lightweight and highly-configurable window manager"
arch=('i686' 'x86_64')
url="http://www.fluxbox.org"
license=('MIT')
depends=('libxft' 'libxpm' 'libxinerama' 'libxrandr' 'gcc-libs' 'sh' 'imlib2' 'fribidi' 
'LinHES-system>=2-52')
makedepends=('pkg-config')
optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
options=('!makeflags')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2 \
        fluxbox.desktop keys fluxbox_fullscreen_focus.patch)
install=fluxbox.install

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  echo "Patching fluxbox"
  patch -p0 < $srcdir/fluxbox_fullscreen_focus.patch || return 1
  echo "Building fluxbox"
  ./configure --prefix=/usr \
    --enable-gnome --enable-xft --enable-xinerama \
    --enable-imlib2 --enable-nls
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../fluxbox.desktop "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
  install -D -m644 ../keys ${pkgdir}/usr/share/$pkgname/keys || return 1
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
md5sums=('0eaa940a69c0a876a520bb85d67b8bec'
         'eeae9c88a2526ac0bd8afcd9ce97f9ed'
         'c6d548dbefd76bad117db23bdf927bcd'
         '7d2fff845c9f951e925b9adcd1053242')