# $Id: PKGBUILD 110541 2011-02-19 21:51:38Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=fluxbox
pkgver=1.3.0
pkgrel=2
pkgdesc="A lightweight and highly-configurable window manager"
arch=('i686' 'x86_64')
url="http://www.fluxbox.org"
license=('MIT')
depends=('libxft' 'libxpm' 'libxinerama' 'libxrandr' 'gcc-libs' 'sh' 'imlib2' 'fribidi')
makedepends=('pkg-config')
optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
options=('!makeflags')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2 \
        fluxbox.desktop keys)

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
    --enable-gnome --enable-xft --enable-xinerama \
    --enable-imlib2 --enable-nls
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../fluxbox.desktop "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
  install -D -m644 ../keys "${pkgdir}/usr/share/fluxbox/keys"
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
md5sums=('817ffe734b8ebb1aa4b9c53ed208c23f'
         'eeae9c88a2526ac0bd8afcd9ce97f9ed'
         'bb9f812c559263b4bf1d722628a11ca8')