# $Id: PKGBUILD 4424 2008-07-06 22:09:03Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=fontconfig
pkgver=2.6.0
pkgrel=4
pkgdesc="A library for configuring and customizing font access"
arch=(i686 x86_64)
url="http://www.fontconfig.org/release/"
license=('custom')
depends=('expat>=2.0' 'freetype2>=2.3.7')
options=('!libtool')
install=fontconfig.install
source=(http://www.fontconfig.org/release/${pkgname}-${pkgver}.tar.gz
	29-replace-bitmap-fonts.conf)
md5sums=('ab54ec1d4ddd836313fdbc0cd5299d6d'
         'f6b67e8cc79197ed6abd4701911e83da')

build() {
  cd ${startdir}/src/${pkgname}-${pkgver}
  # enable Position Independent Code for prelinking
  export CFLAGS="${CFLAGS} -fPIC"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var || return 1
  make || return 1
  make DESTDIR=${startdir}/pkg install || return 1
  install -m644 ${startdir}/src/29-replace-bitmap-fonts.conf \
      ${startdir}/pkg/etc/fonts/conf.avail || return 1
  rm -f ${startdir}/pkg/etc/fonts/conf.d/*.conf

  #Install license
  install -m755 -d ${pkgdir}/usr/share/licenses/${pkgname}
  install -m644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/ || return 1
}