# $Id: PKGBUILD 163618 2012-07-17 05:32:49Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=gpm
pkgver=1.20.6
pkgrel=10
pkgdesc="A mouse server for the console and xterm"
arch=('i686' 'x86_64')
url="http://www.nico.schottelius.org/software/gpm/"
license=('GPL')
depends=('ncurses' 'bash')
backup=('etc/conf.d/gpm')
options=('!makeflags')
install=gpm.install
source=(http://www.nico.schottelius.org/software/gpm/archives/${pkgname}-${pkgver}.tar.lzma \
        gpm gpm.conf.d gpm.sh gpm.service)
sha1sums=('4677da0eb2f1910a5a744bbefa08fea82e0dca0c'
          '19e1feb1493373512a77801699df012d186336ea'
          '4c31cb7dd51cee4d16d3f7a8956e6d87fac1ad86'
          '88fe5ff10916c68a87abc8418a56eb0073f69fa9'
          '20b92360f0ad38a2032fcae37bdbd01b31e43f77')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m755 ../gpm "${pkgdir}/etc/rc.d/gpm"
  install -D -m644 ../gpm.conf.d "${pkgdir}/etc/conf.d/gpm"
  install -D -m755 ../gpm.sh "${pkgdir}/etc/profile.d/gpm.sh"
  install -D -m644 ../gpm.service "${pkgdir}/usr/lib/systemd/system/gpm.service"

# library fixes
  cd "${pkgdir}/usr/lib/"
  ln -s libgpm.so.2.* libgpm.so
  chmod 755 "${pkgdir}"/usr/lib/libgpm.so.*
}