# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=gpm
pkgver=1.20.7
pkgrel=8
pkgdesc="A mouse server for the console and xterm"
arch=('x86_64')
url="http://www.nico.schottelius.org/software/gpm/"
license=('GPL')
depends=('bash' 'procps-ng')
options=('!makeflags')
source=(http://www.nico.schottelius.org/software/gpm/archives/${pkgname}-${pkgver}.tar.lzma
        gpm.sh gpm.service gpm-1.20.7-glibc-2.26-1.patch)

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 < ${srcdir}/gpm-1.20.7-glibc-2.26-1.patch || return 1
  ./autogen.sh
  ./configure --prefix=/usr --sysconfdir=/etc --sbindir=/usr/bin
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m755 ../gpm.sh "${pkgdir}/etc/profile.d/gpm.sh"
  install -D -m644 ../gpm.service "${pkgdir}/usr/lib/systemd/system/gpm.service"

# library fixes
  cd "${pkgdir}/usr/lib/"
  ln -s libgpm.so.2.* libgpm.so
  chmod 755 "${pkgdir}"/usr/lib/libgpm.so.*
}
md5sums=('fa8a6fe09826896625ca557ac5e42ed7'
         'd73dd7e579192a58e5af72be206ce3c8'
         '452cd869cfcc2fd9678f59b3757e4f83'
         'b3554e7a64402f87dd72473727dcd32e')