# $Id: PKGBUILD 89079 2010-08-29 10:28:03Z thomas $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Andrea Scarpino <bash.lnx@gmail.com>

pkgname=ivtv-utils
pkgver=1.4.1
pkgrel=3
pkgdesc="Userspace utilities for Hauppauge PVR cards"
arch=('i686' 'x86_64')
license=('GPL')
url="http://ivtvdriver.org"
source=(http://dl.ivtvdriver.org/ivtv/stable/${pkgname}-${pkgver}.tar.gz
        http://dl.ivtvdriver.org/ivtv/firmware/ivtv-firmware.tar.gz)
depends=('gcc-libs')
install=ivtv-utils.install
md5sums=('3a4219d698262ca2b28e41f0f547b0a2'
         'b9a871f1c569025be9c48a77b3515faf')
 
build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make || return 1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" PREFIX=/usr install

  cd "${srcdir}"
  for file in v4l-cx2341x-dec.fw  v4l-cx2341x-enc.fw v4l-pvrusb2-24xxx-01.fw  v4l-pvrusb2-29xxx-01.fw v4l-cx2341x-init.mpg; do
    install -D -m644 $file "${pkgdir}/lib/firmware/$file"
  done

  # FS#15133 - files already provided by the kernel-headers package
  rm -rf "${pkgdir}"/usr/include
  # Resolve conflict with v4l-utils
  rm -f "${pkgdir}"/usr/bin/v4l2-ctl
}