# $Id: PKGBUILD 161891 2012-06-16 05:10:30Z eric $
# Maintainer:
# Contributor: dorphell <dorphell@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=jade
pkgver=1.2.1
pkgrel=8
_debpatch=47.1
pkgdesc="James Clark's DSSSL Engine"
url='http://www.jclark.com/jade/'
arch=('i686' 'x86_64')
license=('custom')
depends=('gcc-libs')
replaces=('openjade')
options=('!libtool' '!makeflags')
source=("ftp://ftp.jclark.com/pub/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "http://ftp.debian.org/debian/pool/main/j/jade/jade_${pkgver}-${_debpatch}.diff.gz")
md5sums=('4239670ca6b578bff68b8c2e7cd1225f'
         '6c9c0109e3b6d283cb7a18ec8a672575')

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  export CXXFLAGS="$CXXFLAGS -fpermissive"

  patch -p1 -i "${srcdir}"/jade_${pkgver}-${_debpatch}.diff

  chmod 755 configure
  ./configure --prefix=/usr --enable-default-catalog=/usr/share/sgml/catalog

  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  install -d -m755 "${pkgdir}"/usr/lib
  make prefix="${pkgdir}"/usr install
  mv "${pkgdir}"/usr/bin/sx "${pkgdir}"/usr/bin/sgml2xml
  install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}