# $Id: PKGBUILD 88397 2010-08-23 08:25:08Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=libx11
pkgver=1.3.99.903
pkgrel=1
pkgdesc="X11 client-side library"
arch=(i686 x86_64)
url="http://xorg.freedesktop.org/"
depends=('libxcb>=1.7' 'kbproto>=1.0.5')
makedepends=('xproto>=7.0.18' 'xextproto>=7.1.2' 'xf86bigfontproto>=1.2.0' 'xtrans>=1.2.5' 'inputproto>=2.0' 'xorg-util-macros>=1.10.0')
options=('!libtool')
license=('custom:XFREE86')
source=(${url}/releases/individual/lib/libX11-${pkgver}.tar.bz2
        xorg.sh)

build() {
  cd "${srcdir}/libX11-${pkgver}"
  ./configure --prefix=/usr \
      --with-xcb --disable-static
  make || return 1
  make check || return 1
}
package() {
  cd "${srcdir}/libX11-${pkgver}"
  make DESTDIR="${pkgdir}" install || return 1

  install -m755 -d "${pkgdir}/etc/profile.d"
  install -m755 "${srcdir}/xorg.sh" "${pkgdir}/etc/profile.d/"

  install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}

md5sums=('3e8ed7a91f70bb819b5dab9c124a7062'
         '942ff006e69e041f0307c1316e0dec5d')