# $Id$
# Maintainer: Pierre Schmitz <pierre@archlinux.de>

pkgname=lighttpd
pkgver=1.4.51
pkgrel=1
pkgdesc='A secure, fast, compliant and very flexible web-server'
license=('custom')
arch=('i686' 'x86_64')
url="http://www.lighttpd.net/"
depends=('pcre' 'openssl' 'zlib' 'bzip2' 'attr' 'libldap' 'php-cgi')
makedepends=('fcgi' 'libmysqlclient' 'lua' 'libxml2' 'e2fsprogs' 'sqlite' 'gdbm' 'pkgconfig')
optdepends=('libxml2: mod_webdav' \
            'e2fsprogs: mod_webdav' \
            'libmysqlclient: mod_mysql_vhost' \
            'sqlite3: mod_webdav' \
            'gdbm: mod_trigger_b4_dl')
backup=('etc/lighttpd/auth-inc.conf' 'etc/lighttpd/conf.include' 'etc/lighttpd/html.include')
options=('emptydirs')
source=("http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${pkgver}.tar.gz"
        'lighttpd.logrotate.d' 'lighttpd.conf' 'auth-inc.conf' 'ssl-inc.conf'
        'lighttpd.tmpfiles')
install='lighttpd.install'
build() {
	cd ${srcdir}/${pkgname}-${pkgver}

	./configure --prefix=/usr \
        --sbindir=/usr/bin \
		--libexecdir=/usr/lib/lighttpd/modules \
		--sysconfdir=/etc/lighttpd \
		--sharedstatedir=/usr/var \
		--localstatedir=/var \
		--libdir=/usr/lib/lighttpd \
		--includedir=/usr/include/lighttpd \
		--with-mysql \
		--with-ldap \
		--with-attr \
		--with-openssl \
		--with-kerberos5 \
		--without-fam \
		--with-webdav-props \
		--with-webdav-locks \
		--with-gdbm \
		--with-memcache \
		--with-lua || return 1
	make || return 1
}

package() {
    cd ${srcdir}/${pkgname}-${pkgver}
	make DESTDIR=${pkgdir} install || return 1

    install -d -m700 -o http -g http ${pkgdir}/var/{log,cache}/lighttpd/

	install -D -m644 ${srcdir}/lighttpd.logrotate.d ${pkgdir}/etc/logrotate.d/lighttpd
	install -D -m644 ${srcdir}/lighttpd.conf ${pkgdir}/etc/lighttpd/lighttpd.conf
	install -D -m644 ${srcdir}/auth-inc.conf ${pkgdir}/etc/lighttpd/auth-inc.conf
	install -D -m644 ${srcdir}/ssl-inc.conf ${pkgdir}/etc/lighttpd/ssl-inc.conf
    install -D -m644 ${srcdir}/lighttpd.tmpfiles ${pkgdir}/usr/lib/tmpfiles.d/lighttpd.conf

    /usr/bin/touch ${pkgdir}/etc/lighttpd/{conf,html}.include || return 1

	install -D -m644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}
md5sums=('c23b731846163620c24576ec0f145546'
         '42d106b101d21ffd76ed9f3f1621e164'
         'fd4afd737fd16a82ba99b9a99533d34b'
         '62779511e3f1127c3cc9b94c49f99c29'
         'ef64c496602b182a551416a8ba6b3d43'
         '1aeda5526e2cf1ca99d6e1571a6d9cf5')