pkgname=linhes-theme
pkgver=8.4
pkgrel=6
pkgdesc="Default LinHES MythTV theme"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://linhes.org/"

patches=('readme.txt.patch' 'osd.xml.patch' 'base.xml.patch'
         'menu-ui-vert.xml.patch' 'schedule-ui.xml.patch' 'qtlook.txt.patch'
         'recordings-ui.xml.patch' 'video-ui.xml.patch')

#The LinHES theme is based on TintedGlass 4.56 by Harley Peters
source=(`echo ${patches[@]:0}` 'themeinfo.xml' 'install-ui.xml' 'osd_subtitle.xml'
        'bubble_background.png' 'preview.png' 'blank_coverart.png'
        'LHLogo.png' 'LHLogoAndText.png')
install=($pkgname.install)

prepare() {
    _gitroot="https://github.com/MythTV-Themes/TintedGlass.git"
    _gitname="TintedGlass"
    _gitbranch="fixes/0.27"

    cd $srcdir
    if [ -d $_gitname ]
    then
        cd $_gitname 
        git checkout $_gitbranch
        git pull
        msg "TintedGlass local files updated."
    else
        git clone -b $_gitbranch $_gitroot
        msg "TintedGlass git checkout done."
    fi
}

package() {
    THEMEROOT=usr/share/mythtv/themes

    msg "Copying theme to package"
    mkdir -p $pkgdir/$THEMEROOT/LinHES/
    rsync -arp --exclude .git* --delete-excluded $srcdir/TintedGlass/* $pkgdir/$THEMEROOT/LinHES/

    msg "--------------------------applying patches------------------------------"
    cd $pkgdir/$THEMEROOT/LinHES/
    for i in `echo ${patches[@]:0}`
    do
        echo applying $i
        patch -N -i ${srcdir}/$i || return 1
        echo "-----------------------------"
    done
    cd $startdir
    msg "--------------------------done applying patches-------------------------"

    msg "Copy *.xml and adding backgrounds and images for LinHES"
    rsync -pL $srcdir/*.xml $pkgdir/$THEMEROOT/LinHES/
    rm -r $pkgdir/$THEMEROOT/LinHES/images/backgrounds/*
    rsync -pL $srcdir/bubble_background.png $pkgdir/$THEMEROOT/LinHES/images/backgrounds/background.png
    rsync -pL $srcdir/blank_coverart.png $pkgdir/$THEMEROOT/LinHES/images/
    rsync -pL $srcdir/preview.png $pkgdir/$THEMEROOT/LinHES/

    #tux_thoughts.png is the thought bubble for the menu descriptions
    #rsync -pL $srcdir/tux_thoughts.png $pkgdir/$THEMEROOT/LinHES/images/
    rsync -pL $srcdir/LHLogo.png $pkgdir/$THEMEROOT/LinHES/images/
    rsync -pL $srcdir/LHLogoAndText.png $pkgdir/$THEMEROOT/LinHES/images/

    #vertical menu
    mv $pkgdir/$THEMEROOT/LinHES/menu-ui-vert.xml $pkgdir/$THEMEROOT/LinHES/menu-ui.xml

    msg "Modifying yellows and blue to LinHES yellow and blue"
    #yellow
    grep -lr '#d9d900' $pkgdir/$THEMEROOT/LinHES/ | xargs sed -i "s/\#d9d900/\#ebb81c/g"
    #darkyellow
    grep -lr '#CCCC29' $pkgdir/$THEMEROOT/LinHES/ | xargs sed -i "s/\#CCCC29/\#ebb81c/g"
    #blue
    grep -lr '#3a9ade' $pkgdir/$THEMEROOT/LinHES/ | xargs sed -i "s/\#3a9ade/\#0072bc/g"

    msg "Modifying fonts to Overlock"
    grep -lr 'DejaVu Sans' $pkgdir/$THEMEROOT/LinHES/ | xargs sed -i "s/\DejaVu Sans/\Overlock/g"

    msg "Updating themeinfo.xml version number"
    IFS="." read -a array <<< "$pkgver"
    sed -i "s/MAJ_VER/${array[0]}/" $pkgdir/$THEMEROOT/LinHES/themeinfo.xml
    sed -i "s/MIN_VER/${array[1]}${pkgrel}/" $pkgdir/$THEMEROOT/LinHES/themeinfo.xml
}
md5sums=('2dca856c2a4d1f959473512c94e43b60'
         '985f76e26a526e0727ec7afc44cf9b8c'
         'f2b9c85519e80843294315a42870e582'
         '43b1f213fd392fb07aac503e775e27bc'
         '22ff4044c8c29560451fb51dcbf4d44e'
         '9fe3371a8b964a7028126405cfaa330b'
         'e88dc1587a164aaa15b280cb66f6a82b'
         '59b43ab3c40390ad4184883a5e23a16a'
         '5a8fb2a5f0e657d52be6f0a6a006ce72'
         '35d77d91125e46728a30ab23d0903223'
         'bfc32b9fa5dca3d46dd6f365ecb449b5'
         '326a71eb795b322a9ea26f116d890c87'
         '8fcd0acc11f4db33a9442949fb1a293d'
         '699e3abe05523f454db3561bfc08b4b2'
         'b51ef0cbf8ed2d3a8c1a8257a89aceff'
         '09ad14842f828b7a8d24070ec8214fe5')