# $Id$
# Maintainer: Thomas Bächler <thomas@archlinux.org>

#
# Create a new tarball from the linux-firmware git tree with the following command:
# git clone git://git.kernel.org/pub/scm/linux/kernel/git/firmware/linux-firmware.git
# git archive --format=tar --prefix linux-firmware-$(date +%Y%m%d)/ master | xz -9 > linux-firmware-$(date +%Y%m%d).tar.xz
#

pkgname=linux-firmware
pkgver=20120227
pkgrel=1
pkgdesc="Firmware files for Linux"
arch=('any')
url="http://git.kernel.org/?p=linux/kernel/git/dwmw2/linux-firmware.git;a=summary"
license=('GPL2' 'GPL3' 'custom')
provides=('kernel26-firmware=2.6.34.99')
conflicts=('linux-firmware-git'
           'kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw')
replaces=('kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw')
options=(!strip)
source=(v4l-cx23885-enc.fw
        ftp://ftp.archlinux.org/other/linux-firmware/$pkgname-$pkgver.tar.xz)
#sha256sums=('bc1cbee23ab8be8478be66e5486008d81b91fbf6de50347fd1be58b5e56bc6b7')

package() {
  #copy in correct firmware
  install -D -m755 "${srcdir}/v4l-cx23885-enc.fw" "${srcdir}/${pkgname}-${pkgver}/"

  cd "${srcdir}/${pkgname}-${pkgver}"

  install -d -m755 "${pkgdir}/lib/firmware"
  cp -a * "${pkgdir}/lib/firmware/"
  install -d -m755 "${pkgdir}/usr/share/licenses/linux-firmware/"
  rm -f "${pkgdir}/lib/firmware/GPL*"
  mv "${pkgdir}/lib/firmware"/{LICEN*,WHENCE} "${pkgdir}/usr/share/licenses/linux-firmware/"
}
md5sums=('1cb3c48a6684126f5e503a434f2d636b'
         '80084f057b8942421dd132a7ac78c3e8')
# vim:set ts=2 sw=2 et: