# $Id: PKGBUILD 85247 2010-07-11 09:33:36Z thomas $
# Maintainer: Thomas Bächler <thomas@archlinux.org>

#
# Create a new tarball from the linux-firmware git tree with the following command:
# git archive --format=tar --prefix linux-firmware-$(date +%Y%m%d)/ master | xz -9 > linux-firmware-$(date +%Y%m%d).tar.xz
#

pkgname=linux-firmware
pkgver=20100623
pkgrel=2
pkgdesc="Firmware files for Linux"
arch=('any')
url="http://git.kernel.org/?p=linux/kernel/git/dwmw2/linux-firmware.git;a=summary"
license=('GPL2' 'GPL3' 'custom')
provides=('kernel26-firmware=2.6.34.99')
conflicts=('linux-firmware-git'
           'kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw')
replaces=('kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw')
options=(!strip)
source=(ftp://ftp.archlinux.org/other/linux-firmware/$pkgname-$pkgver.tar.xz
        http://www.kernel.org/pub/linux/kernel/people/mcgrof/firmware/ar9170/ar9170.fw)
sha256sums=('f78f96a4d330ecded5e6a6e61c1e6f2cdf915625b65040f4bd3e6dfea44f367d'
            '1b379c5a8d6ab3a43911f7949d6306fe2dae3afb1368be5452a8fc7d9c54e0a0')
package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  install -d -m755 "${pkgdir}/lib/firmware"
  cp -a * "${pkgdir}/lib/firmware/"
  install -d -m755 "${pkgdir}/usr/share/licenses/linux-firmware/"
  rm -f "${pkgdir}/lib/firmware/GPL*"
  mv "${pkgdir}/lib/firmware"/{LICEN*,WHENCE} "${pkgdir}/usr/share/licenses/linux-firmware/"

  # Add missing firmware files
  # https://bugs.archlinux.org/task/19912
  cd "${pkgdir}/lib/firmware/bnx2"
  ln -s bnx2-mips-09-5.0.0.j15.fw bnx2-mips-09-5.0.0.j9.fw
  cd -
  # https://bugs.archlinux.org/task/20064
  install -m644 "${srcdir}/ar9170.fw" "${pkgdir}/lib/firmware/"
}
# vim:set ts=2 sw=2 et: