# $Id: PKGBUILD 95239 2010-10-17 16:13:26Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=mtools
pkgver=4.0.14
pkgrel=1
pkgdesc="A collection of utilities to access MS-DOS disks"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/mtools/"
license=('GPL')
depends=('sh')
makedepends=('texinfo' 'libx11' 'libsm')
optdepends=('libx11: required by floppyd'
	    'libsm:  required by floppyd')
backup=('etc/mtools.conf')
install=mtools.install
source=(http://ftp.gnu.org/gnu/mtools/${pkgname}-${pkgver}.tar.bz2)
md5sums=('2682a2db57b0144fa2ad6f8794320fb8')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  sed -i '/^SAMPLE FILE$/s:^:# :' mtools.conf
  ./configure --prefix=/usr \
              --mandir=/usr/share/man \
              --infodir=/usr/share/info \
	      --sysconfdir=/etc
  make || return 1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make -j 1 DESTDIR="${pkgdir}" install || return 1
  install -Dm644 mtools.conf "${pkgdir}/etc/mtools.conf" || return 1
}