pkgname=mythtv
pkgver=0.28
pkgrel=11
commit_hash=`cat ../git_src/git_hash`
pkgdesc="A Homebrew PVR project $commit_hash"
arch=('i686' 'x86_64')
url="http://www.mythtv.org/"
license=('GPL')
depends=('avahi' 'faad2' 'fftw' 'glew' 'exiv2' 'lame' 'libass' 'libavc1394' 'libcdio'
         'libcec' 'libcrystalhd-git' 'libiec61883' 'libva' 'libvdpau' 'libvpx'
         'libxinerama' 'libxrandr' 'libxml2' 'LinHES-config>=8.1-6'
         'LinHES-system>=8.4-4' 'lirc-utils' 'mysql-clients' 'mysql-python'
         'openssl' 'perl-date-manip' 'perl-dbd-mysql'
         'perl-io-socket-inet6' 'perl-libwww' 'perl-math-round'
         'perl-net-upnp' 'perl-soap-lite' 'perl-xml-sax' 'python2-pycurl'
         'python2-lxml' 'qt5-script' 'qt5-webkit' 'sdl' 'taglib' 'urlgrabber' 'wget'
         'x264' 'xmltv')
makedepends=('mesa' 'libgl' 'yasm' 'git' 'rsync')
replaces=()
groups=('pvr')
backup=()
install='mythtv.install'

patches=(
         'myth_settings.patch'
         'videoAlwaysUseBookmark.patch'
         'mediamonitor_use_1st_handler.patch'
         'autoskip_reduce_commskip_jumpback.patch'
         'change_msg_types.patch'
         'disable_mythnotification_tuner_failure.patch'
         'tv.cpp_fix_caps.patch'
         'add_categorytype_Program.pm.patch'
         )

optdepends=()
source=(`echo ${patches[@]:0}` 'recordings')

build() {
    if [ -e ${srcdir}/mythtv ]
    then
        msg "Removing old mythtv src"
        rm -rf ${srcdir}/mythtv
    fi

    cd ${startdir}
    msg "Copying in mythtv git_src"
    cp -rp ../git_src/mythtv/mythtv $srcdir
    cd ${srcdir}/$pkgname
    echo "#!/bin/bash" > version.sh

    msg "--------------------------applying patches------------------------------"
    for i in `echo ${patches[@]:0}`
    do
        echo applying $i
        patch -Np2  -i ${startdir}/src/$i  || return 1
        echo "-----------------------------"
    done
    msg "--------------------------done applying patches-------------------------"

    msg "Configuring mythtv"
    ARCH=${CARCH/_/-}
    #disable mythlogserver due to http://code.mythtv.org/trac/ticket/11230
    ./configure --prefix=/usr \
                --cpu=${ARCH} \
                --disable-altivec \
                --disable-audio-jack \
                --disable-audio-pulseoutput \
                --disable-distcc \
                --disable-mythlogserver \
                --dvb-path=/usr/include \
                --enable-libmp3lame \
                --enable-libvpx \
                --enable-libxvid \
                --enable-libx264 \
                --enable-sdl \
                --python=python2 \
                --with-bindings=perl,python || return 1
    msg "Compiling mythtv"
    make all || return 1
}

package() {
    cd "${srcdir}/${pkgname}"
    # basic install
    make INSTALL_ROOT="${pkgdir}" install
    # install contrib files
    rsync -arp --exclude .svn --delete-excluded contrib ${pkgdir}/usr/share/mythtv/ || return 1
    # install database structure
    rsync -arp --exclude .svn --delete-excluded database ${pkgdir}/usr/share/mythtv/ || return 1
    # install docs
    rsync -arp --exclude .svn --delete-excluded docs ${pkgdir}/usr/share/mythtv/ || return 1

    # patch the xml LinHES style
    cp -r ${startdir}/menu-xml/*.xml ${pkgdir}/usr/share/mythtv/themes/defaultmenu/
    cd ${pkgdir}/usr/share/mythtv
    patch -p0 < ${startdir}/menu-xml/mainmenu.xml.patch || return 1
    patch -p0 < ${startdir}/menu-xml/optical_menu.xml.patch || return 1
    patch -p0 < ${startdir}/menu-xml/library.xml.patch || return 1

    # make mythtv log dir for old scripts that use it
    mkdir -p ${pkgdir}/var/log/mythtv
    chown 1000.1000 ${pkgdir}/var/log/mythtv

    #install recordings (was pretty)
    mkdir -p ${pkgdir}/etc/cron.hourly/
    install -m0755 ${srcdir}/recordings ${pkgdir}/etc/cron.hourly/
}

md5sums=('e30b482dcd5f3e71c6419fd753bab2b1'
         '41098e898361a5a3cde3eaae358482a8'
         '8d26b14af13b7be242ba999a8521f8dd'
         '0bf5e92c0609a7eda8f253bf2e032590'
         'f8a56ac814722b110dc9859169b9bda9'
         '1cd668136deea20efb79cf3e6310effc'
         '62c42b1043ebf65959fa9eced9ca3ed8'
         'a38f26576662afdc02d11c7096839321'
         'cc9e81a297f82e9df4ad72428c4f37c6')