pkgbase=mythplugins
pkgname=('mytharchive'
         'mythbrowser'
         'mythgallery'
         'mythgame'
         'mythmusic'
         'mythnetvision'
         'mythnews'
         'mythweather'
         'mythzoneminder')
pkgver=30.0
pkgrel=11
arch=('x86_64')
url="http://www.mythtv.org"
license=('GPL')
makedepends=('cdrkit' 'dcraw' 'dvdauthor' 'dvd+rw-tools' 'ffmpeg' 'flac' 'libexif'
             'libvorbis' 'mesa' 'libgl' 'mplayer' "mythtv>=${pkgver}"
             'perl-datetime-format-iso8601' 'perl-date-manip' 'perl-image-size'
             'perl-json' 'perl-libwww' 'perl-soap-lite' 'perl-xml-sax'
             'perl-xml-simple' 'perl-xml-xpath' 'python2-oauth' 'python2-pillow'
             'python2-pycurl' 'qt5-tools' 'zlib')
source=('mythburn.py-aspectratio.patch'
        'mythburn.cpp-python2.patch'
        '0317-0336-MythMusic-Fix-Playlist-copyTracks-and-removeAllTrack.patch'
        'mythmusic_en_us.ts_Title_Case.patch'
        )

prepare() {
    if [ -e ${srcdir}/mythplugins ]
    then
        msg "Removing old mythplugins src"
        rm -rf ${srcdir}/mythplugins
    fi

    cd ${startdir}
    msg "Copying in mythplugins git_src"
    cp -rp ../git_src/mythtv/mythplugins $srcdir

    msg "Patch MythMusic Playlist"
    cd ${srcdir}
    patch -Np1 -i "$srcdir/0317-0336-MythMusic-Fix-Playlist-copyTracks-and-removeAllTrack.patch"

    msg "Change python to python2"
    find . -name '*.py' -type f | xargs sed -i 's@^#!.*python$@#!/usr/bin/python2@'
    patch -Np1 -i "$srcdir/mythburn.cpp-python2.patch"

    msg "Patch and update MythMusic translations"
    patch -Np1 -i "$srcdir/mythmusic_en_us.ts_Title_Case.patch"
    cd ${srcdir}/$pkgbase/mythmusic/i18n
    lrelease -removeidentical mythmusic_en_us.ts
}

build() {
    cd ${srcdir}/${pkgbase}
    msg "Configuring mythplugins"
    ./configure --prefix=/usr \
                --enable-all \
                --python=python2

    msg "Compiling mythplugins"
    qmake-qt5 mythplugins.pro || return 1
    make || return 1
}

package_mytharchive() {
    pkgdesc="Create DVDs or archive recorded shows in MythTV"
    depends=('cdrkit' 'dvdauthor' 'dvd+rw-tools' 'ffmpeg' "mythtv>=${pkgver}"
             'm2vrequantiser' 'mjpegtools' 'python2-pillow')
    optdepends=('projectx: for subtitle support')
    cd "${srcdir}/${_gitname}/${pkgbase}/mytharchive"
    patch mythburn/scripts/mythburn.py < $srcdir/mythburn.py-aspectratio.patch || return 1
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythbrowser() {
    pkgdesc="Mini web browser for MythTV"
    depends=("mythtv>=${pkgver}")
    cd "${srcdir}/${_gitname}/${pkgbase}/mythbrowser"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythgallery() {
    pkgdesc="Image gallery plugin for MythTV"
    depends=('libexif' "mythtv>=${pkgver}" 'dcraw')
    cd "${srcdir}/${_gitname}/${pkgbase}/mythgallery"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythgame() {
    pkgdesc="Game emulator plugin for MythTV"
    depends=("mythtv>=${pkgver}" 'zlib')
    cd "${srcdir}/${_gitname}/${pkgbase}/mythgame"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythmusic() {
    pkgdesc="Music playing plugin for MythTV"
    depends=('cdparanoia' 'fftw' 'flac' 'libcdaudio' 'libcdio-paranoia' 
             'libvisual-plugins' 'libvorbis' "mythtv>=${pkgver}" 'taglib')
    cd "${srcdir}/${_gitname}/${pkgbase}/mythmusic"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythnetvision() {
    pkgdesc="MythNetvision plugin for MythTV"
    depends=("mythtv>=${pkgver}" 'python2-pycurl' 'python2-oauth'
             'python2-lxml' 'python2')
    cd "${srcdir}/${_gitname}/${pkgbase}/mythnetvision"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythnews() {
    pkgdesc="News checking plugin for MythTV"
    depends=("mythtv>=${pkgver}")
    cd "${srcdir}/${_gitname}/${pkgbase}/mythnews"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythweather() {
    pkgdesc="Weather checking plugin for MythTV"
    depends=("mythtv>=${pkgver}" 'perl-date-manip' 'perl-json' 'perl-soap-lite'
             'perl-xml-sax' 'perl-xml-simple' 'perl-xml-xpath' 'perl-image-size'
             'perl-datetime-format-iso8601')
    cd "${srcdir}/${_gitname}/${pkgbase}/mythweather"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

package_mythzoneminder() {
    pkgdesc="View CCTV footage from zoneminder in MythTV"
    depends=("mythtv>=${pkgver}")
#    install=mythplugins-mythzoneminder.install
    cd "${srcdir}/${_gitname}/${pkgbase}/mythzoneminder"
    make INSTALL_ROOT="${pkgdir}" install || return 1
}

md5sums=('e98c2a09bcb051fdde959fb4bb2e5ab2'
         'b9edd8f7da64ffa74baa91092bd48cc9'
         '0299d0214c0d3a452c0284352435d698'
         'df4b92d6886db1fdd59fc02dbe33df60')