# Maintainer: Justin Davis <jrcd83@gmail.com>
# $Id: PKGBUILD 57540 2011-10-30 17:10:04Z juster $

pkgname=perl-try-tiny
pkgver=0.11
pkgrel=1
pkgdesc="minimal try/catch with proper localization of \$@"
arch=(any)
license=(PerlArtistic GPL)
options=(!emptydirs)
makedepends=('perl-extutils-makemaker')
checkdepends=('perl-test-simple')
url=https://metacpan.org/release/Try-Tiny
source=("http://search.cpan.org/CPAN/authors/id/D/DO/DOY/Try-Tiny-${pkgver}.tar.gz")
md5sums=(4d2c8ff385ac3513edf4c042dd0eacbe)
sha512sums=(42a98d0996e4195b1618e99080f67791ec9b09c8c4de669aafcbe75c609718d700a6831dd5a68d8f7bda563c29ce3a8495bbf548b8d38a155471875889d8c701)
_distdir="${srcdir}/Try-Tiny-${pkgver}"

build() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
      PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
      MODULEBUILDRC=/dev/null

    cd "$_distdir"
    /usr/bin/perl Makefile.PL
    make
  )
}

check() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    cd "$_distdir"
    make test
  )
}

package() {
    cd "$_distdir"
    make DESTDIR="$pkgdir" install
    find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et: