# $Id: PKGBUILD 140196 2011-10-09 08:27:16Z angvp $
# Maintainer: Angel Velasquez <angvp@archlinux.org> 
# Contributor: Sergej Pupykin <sergej@aur.archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=python2-m2crypto
pkgver=0.27.0
pkgrel=1
pkgdesc="A crypto and SSL toolkit for Python"
arch=('x86_64')
url="https://pypi.python.org/pypi/M2Crypto"
license=('BSD')
depends=('python2' 'openssl' 'python2-typing')
makedepends=('swig' 'python2-setuptools')
source=("https://pypi.python.org/packages/01/bd/a41491718f9e2bebab015c42b5be7071c6695acfa301e3fc0480bfd6a15b/M2Crypto-$pkgver.tar.gz"
	"LICENSE")
sha256sums=('82317459d653322d6b37f122ce916dc91ddcd9d1b814847497ac796c4549dd68'
            '4eca478396f4b2b020729a111fce3f096456d74500bfd8f2b0388c3c69f997c0')

build() {
  cd "${srcdir}/M2Crypto-${pkgver}"
  python2 setup.py build
}

package() {
  cd "${srcdir}/M2Crypto-${pkgver}"
  python2 setup.py install --root="${pkgdir}/" --optimize=1
  install -D -m644 "$srcdir"/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}