# $Id: PKGBUILD 58329 2011-11-11 14:26:11Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=rsyslog
pkgver=5.8.6
pkgrel=12
pkgdesc="An enhanced multi-threaded syslogd with a focus on security and reliability"
url="http://www.rsyslog.com/"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('zlib')
makedepends=( 'libmysqlclient'  'gnutls')
optdepends=( 'libmysqlclient: MySQL Database Support'
	    'gnutls')
backup=('etc/rsyslog.conf' \
	'etc/conf.d/rsyslog')
conflicts=('syslog-ng')
replaces=('syslog-ng')
groups=('base')
 
options=('strip' 'zipman' '!libtool')
#install=('rsyslog.install')
source=("http://www.rsyslog.com/files/download/rsyslog/rsyslog-$pkgver.tar.gz"
        'rsyslog' 'rsyslog.conf.d' 'rsyslog.conf.linhes' 'mythtv.conf'
        'log_care.sh')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr \
	      --sbindir=/usr/bin \
              --enable-mysql \
              --enable-mail \
              --enable-imfile \
              --enable-imtemplate \
              --enable-gnutls \
              --enable-inet \
              --with-systemdsystemunitdir=/usr/lib/systemd/system
  make
}
package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make install DESTDIR=${pkgdir}
  # Install Daemons and Configuration Files
  install -D -m755 ${srcdir}/${pkgname} ${pkgdir}/etc/rc.d/${pkgname}d
  install -D -m644 ${srcdir}/${pkgname}.conf.linhes ${pkgdir}/etc/${pkgname}.conf
  install -D -m644 ${srcdir}/mythtv.conf ${pkgdir}/etc/rsyslog.d/mythtv.conf
  install -D -m644 ${srcdir}/${pkgname}.conf.d ${pkgdir}/etc/conf.d/${pkgname}
  install -D -m755 ${srcdir}/log_care.sh ${pkgdir}/etc/cron.daily/log_care
}
md5sums=('c46db0496066b82faf735bd4222208d7'
         'a18bbcbb6ebdaa13a6ec6d9f3d9eb2da'
         '1a0cd4530dd5d1439456d5ae230574d9'
         'a4dd3846116b02f35d48c8987b30394b'
         'c71fa75857ff7b9e24e41457e89c76ca'
         'cd39e6edc1fcbbae2093c40c880e0079')