# $Id: PKGBUILD 168539 2012-10-13 09:28:52Z thomas $
# Maintainer: Eric Belanger <eric@archlinux.org>

pkgbase=sysvinit
pkgname=('sysvinit-tools' 'sysvinit' )
pkgver=2.88
pkgrel=9
arch=('i686' 'x86_64')
url="http://savannah.nongnu.org/projects/sysvinit"
license=('GPL')
depends=('util-linux' 'coreutils' 'glibc' 'awk' 'poweroff-scripts')
source=(http://download.savannah.gnu.org/releases/sysvinit/${pkgbase}-${pkgver}dsf.tar.bz2
        "0001-simplify-writelog.patch"
        "0002-remove-ansi-escape-codes-from-log-file.patch"
	"halt_init.patch")

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}dsf"

  # FS#30005
  patch -p1 -d "src" -i "${srcdir}/0001-simplify-writelog.patch"
  patch -p1 -d "src" -i "${srcdir}/0002-remove-ansi-escape-codes-from-log-file.patch"
  patch -p0 < ${srcdir}/halt_init.patch
  make 
}

package_sysvinit-tools() {
  pkgdesc="Linux System V Init Tools"
  depends=('poweroff-scripts')
  cd "${srcdir}/${pkgbase}-${pkgver}dsf"
  make ROOT="${pkgdir}" install

  # provided by util-linux
  cd "${pkgdir}"
  rm bin/mountpoint
  rm usr/share/man/man1/mountpoint.1
  rm usr/bin/{mesg,utmpdump,wall}
  rm usr/share/man/man1/{mesg,utmpdump,wall}.1
  rm sbin/sulogin
  rm usr/share/man/man8/sulogin.8

  ### split out sysvinit
  rm -rf ${srcdir}/_sysvinit
  install -dm755 \
        ${srcdir}/_sysvinit/sbin \
        ${srcdir}/_sysvinit/usr/share/man/man8
  cd ${srcdir}/_sysvinit
  mv ${pkgdir}/sbin/{halt,init,poweroff,reboot,runlevel,shutdown,telinit} sbin/
  mv ${pkgdir}/usr/share/man/man5 usr/share/man/
  mv ${pkgdir}/usr/share/man/man8/{halt,init,poweroff,reboot,runlevel,shutdown,telinit}.8 usr/share/man/man8/
}

package_sysvinit() {
  pkgdesc="Linux System V Init"
  depends=('sysvinit-tools')
  install=sysvinit.install
  # Rename some stuff so it does not bigfoot changes needed for runit
  cd "${srcdir}/_sysvinit/sbin"
  rm -f reboot poweroff
  mv halt halt.init
  mv shutdown shutdown.init
  mv "${srcdir}"/_sysvinit/* $pkgdir
}
md5sums=('6eda8a97b86e0a6f59dabbf25202aa6f'
         'e3e82a3a38415518f52f78a622ef0262'
         '04f0ab28340df08bb47d066669bc4519'
         'aec0de91c1d2f56e78393d400fd238a7')