# $Id: PKGBUILD 356 2008-04-18 22:56:27Z aaron $
# Maintainer: judd <jvinet@zeroflux.org>
pkgname=util-linux-ng
pkgver=2.14
pkgrel=10
pkgdesc="Miscellaneous system utilities for Linux"
arch=('i686' 'x86_64')
groups=('base')
depends=('bash' 'ncurses' 'zlib' 'e2fsprogs')
replaces=('linux32' 'util-linux')
conflicts=('linux32' 'util-linux')
provides=('linux32' 'util-linux')
license=('GPL')
source=(ftp://ftp.kernel.org/pub/linux/utils/${pkgname}/v2.14/${pkgname}-${pkgver}.tar.bz2
	util-linux-ng-2.14-20080624.diff)
md5sums=('23f227da49df36f33fe47e917e332cd8'
	 'acb7bf692d239eb9872b0f00de437b7e')

# The cryptoloop-support.patch comes from the boys at Rock Linux
#   (http://www.rocklinux.net/packages/util-linux.html)

# Newer crypt support is here:
#    http://loop-aes.sourceforge.net/updates/util-linux-${_realver}.diff.bz2

build() {
  cd ${startdir}/src/${pkgname}-${pkgver}
  ./autogen.sh
  # cryptoloop support
  patch -Np1 -i ${startdir}/src/util-linux-ng-2.14-20080624.diff || return 1
  sed -e 's%etc/adjtime%var/lib/hwclock/adjtime%' -i hwclock/hwclock.c 
  mkdir -p ${startdir}/pkg/var/lib/hwclock
  ./configure --enable-arch --enable-write --enable-raw --disable-wall --enable-rdev
  make HAVE_SLN=yes ADD_RAW=yes || return 1
  make HAVE_SLN=yes ADD_RAW=yes DESTDIR=${startdir}/pkg install
  rm -f ${startdir}/pkg/bin/kill
  rm -f ${startdir}/pkg/usr/share/man/man1/kill.1
  rm -f ${startdir}/pkg/usr/share/man/man5/nfs.5
}