# $Id: PKGBUILD 29509 2009-03-09 17:25:09Z tpowa $
# Maintainer: judd <jvinet@zeroflux.org>
pkgname=util-linux-ng
pkgver=2.14.2
_loop_date=20090214
pkgrel=1
pkgdesc="Miscellaneous system utilities for Linux"
url="http://userweb.kernel.org/~kzak/util-linux-ng/"
arch=('i686' 'x86_64')
groups=('base')
depends=('bash' 'ncurses>=5.7' 'zlib' 'e2fsprogs')
replaces=('linux32' 'util-linux')
conflicts=('linux32' 'util-linux')
provides=('linux32' 'util-linux')
license=('GPL2')
source=(ftp://ftp.kernel.org/pub/linux/utils/${pkgname}/v2.14/${pkgname}-${pkgver}.tar.bz2
	http://loop-aes.sourceforge.net/updates/${pkgname}-${pkgver}-${_loop_date}.diff.bz2)
install=util-linux-ng.install
md5sums=('b9d0053a22cfcbf0b9c0aa6d6eccfbc8'
         '72c5b3e961efc1bda2750dbad019e414')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # cryptoloop support
  patch -Np1 -i ${srcdir}/${pkgname}-${pkgver}-${_loop_date}.diff || return 1
  # hardware clock
  sed -e 's%etc/adjtime%var/lib/hwclock/adjtime%' -i hwclock/hwclock.c 
  mkdir -p ${startdir}/pkg/var/lib/hwclock
  ./configure --enable-arch --enable-write --enable-raw --disable-wall --enable-rdev
  make HAVE_SLN=yes ADD_RAW=yes || return 1
  make HAVE_SLN=yes ADD_RAW=yes DESTDIR=${startdir}/pkg install || return 1
  # remove files
  rm -f ${pkgdir}/bin/kill
  rm -f ${pkgdir}/usr/share/man/man1/kill.1
  rm -f ${pkgdir}/usr/share/man/man5/nfs.5
  rm -f ${pkgdir}/usr/share/info/dir
}