# Contributor: Troy Will                 <troydwill@gmail.com>
# Contributor: /dev/rs0                  </dev/rs0@secretco.de.com>
# Contributor: Jacek Burghardt           <jacek@hebe.us>
# Contributor: Vojtech Aschenbrenner     <v@asch.cz>
# Contributor: Jason Gardner             <buhrietoe@gmail.com>
# Contributor: Ross melin                <rdmelin@gmail.com>
# Contributor (Parabola): Márcio Silva   <coadde@lavabit.com>
# Contributor (Parabola): André Silva    <emulatorman@lavabit.com>
# Orginally based on a Debian Squeeze package
     
pkgbase=zoneminder
pkgname=zoneminder
pkgver=1.28.0
pkgrel=5
pkgdesc='Capture, analyse, record and monitor video security cameras'
arch=( i686 x86_64 mips64el arm )
     
backup=( etc/zm.conf )
url="https://github.com/ZoneMinder/ZoneMinder/releases"
license=( GPL )
     
depends=(
    lighttpd
    cambozola
    gnutls
    mysql
    perl-archive-zip
    perl-date-manip
    perl-dbd-mysql
    perl-dbi
    perl-expect
    perl-libwww
    perl-mime-lite
    perl-mime-tools
    perl-php-serialization
    perl-net-sftp-foreign
    perl-sys-mmap
    perl-time-modules
    perl-x10
    php
    #php-apache
    php-gd
    php-mcrypt
)

makedepends=(
    netpbm
    cmake
)

optdepends=(
    netpbm
)
     
install=$pkgbase.install
     
source=(
    https://github.com/ZoneMinder/ZoneMinder/archive/v$pkgver.tar.gz
    httpd-zoneminder.conf
    zoneminder.service
    zm.include
    zm.sysctrl.conf    
    zm_gen_light.conf
)

     
build() {
    cd $srcdir/ZoneMinder-$pkgver

    cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DZM_CGIDIR=/data/srv/httpd/cgi-bin \
        -DZM_WEBDIR=/data/srv/httpd/zoneminder \
        -DZM_WEB_USER=http \
        -DZM_CONTENTDIR=/var/cache/zoneminder \
        -DZM_LOGDIR=/var/log/zoneminder \
        -DZM_RUNDIR=/var/run/zm \
        -DZM_TMPDIR=/var/tmp \
        -DZM_SOCKDIR=/data/srv/zoneminder/socks/ .
    
    make V=0
}
     
package() {

    cd $srcdir/ZoneMinder-$pkgver

    DESTDIR=$pkgdir make install

    # BEGIN CREATE_ZONEMINDER_DIRECTORIES
    mkdir -p $pkgdir/var/run/zm
    chown -v http.http $pkgdir/var/run/zm
    mkdir -p $pkgdir/var/{cache/$pkgbase,log/$pkgbase}
    mkdir -p $pkgdir/data/srv/zoneminder/socks
    chown -Rv http.http $pkgdir/{etc/zm.conf,var/{cache/$pkgbase,log/$pkgbase}}
    chown -Rv http.http $pkgdir/data/srv/zoneminder/socks
    chmod 0700 $pkgdir/etc/zm.conf
    # END CREATE_ZONEMINDER_DIRECTORIES

    # Make content directories in /var/cache/zoneminder and link them
    for i in events images temp; do
        mkdir $pkgdir/var/cache/$pkgbase/$i
        # chown -v    http.http                $pkgdir/var/cache/$pkgbase/$i
        ln -s /var/cache/$pkgbase/$i         $pkgdir/data/srv/httpd/$pkgbase/$i
        chown -v --no-dereference http.http  $pkgdir/data/srv/httpd/$pkgbase/$i
    done

    # Create a link to the Zoneminder cgi binaries
    ln -sv /data/srv/httpd/cgi-bin $pkgdir/data/srv/httpd/$pkgbase

    chown -h http.http $pkgdir/data/srv/httpd/{cgi-bin,$pkgbase,$pkgbase/cgi-bin}

    # Link Cambozola
    ln -s /usr/share/cambozola/cambozola.jar $pkgdir/data/srv/httpd/$pkgbase

    # Install configuration files
# don't need these in LinHES as we use lighttpd not apache
#    mkdir -p $pkgdir/etc/httpd/conf/extra
#    install -D -m 644 $srcdir/httpd-$pkgbase.conf $pkgdir/etc/httpd/conf/extra
    mkdir -p $pkgdir/usr/lib/systemd/system
    install -D -m 644 $srcdir/$pkgbase.service    $pkgdir/usr/lib/systemd/system
    install -D -m 644 COPYING                     $pkgdir/usr/share/license/$pkgbase
    install -D -m 644 db/zm*.sql                  $pkgdir/usr/share/$pkgbase/db     

    #LinHES stuff
    #lighttpd zm include
    install -D -m644 $srcdir/zm.include $pkgdir/etc/lighttpd/zm.include
    #sysctrl conf - to set the shared mem
    install -o root -g root -D -m0755 $srcdir/zm.sysctrl.conf $pkgdir/etc/sysctl.d/zm.conf
    #gen_light_conf
    install -D -m0744 ${srcdir}/zm_gen_light.conf $pkgdir/etc/gen_light_conf.d/zoneminder.conf
}
md5sums=('b0317c6fe003de9a0c7c76078b0adc2b'
         'dcaa22b9030bc7b5b76568dbe8ea9eca'
         'bb801be691cbe1ed98f395b2ebe5c882'
         '9d93f9b7b0a1384df533efde19ed3021'
         'c528e75443ae421cb7f63e12350c692a'
         '81cb12b36616a299ec808ac70a809ec2')