# Maintainer: Geoffroy Carrier <geoffroy@archlinux.org>
pkgname=bluez
pkgver=4.69
pkgrel=1
pkgdesc="Libraries and tools for the Bluetooth protocol stack"
url="http://www.bluez.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus-core' 'glib2')
makedepends=('gstreamer0.10-base' 'alsa-lib' 'libusb')
optdepends=('gstreamer0.10-base' 'alsa-lib' 'libusb')
conflicts=('bluez-libs' 'bluez-utils')
provides=('bluez-libs' 'bluez-utils')
replaces=('bluez-libs' 'bluez-utils')
install='bluez.install'
backup=(etc/bluetooth/{main,rfcomm,audio,network,input}.conf
        etc/conf.d/bluetooth)
source=("http://www.kernel.org/pub/linux/bluetooth/$pkgname-$pkgver.tar.bz2"
        bluetooth.conf.d run.bluetoothd run.hidd run.dund run.pand
        run.rfcomm)

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr \
        --sysconfdir=/etc \
        --localstatedir=/var \
        --libexecdir=/lib \
        --mandir=/usr/share/man \
        --enable-gstreamer \
        --enable-alsa \
        --enable-usb \
        --enable-netlink \
        --enable-tools \
        --enable-bccmd \
        --enable-hid2hci \
        --enable-dfutool \
        --enable-hidd \
        --enable-pand \
        --enable-dund \
        --enable-cups \
        --enable-manpages \
        --enable-configfiles \
        --enable-pcmciarules || return 1
  make || return 1
  make DESTDIR="$pkgdir" install || return 1

  install -D -m644 "$srcdir/$pkgname-$pkgver/network/network.conf" "$pkgdir/etc/bluetooth/" || return 1
  install -D -m644 "$srcdir/$pkgname-$pkgver/input/input.conf"     "$pkgdir/etc/bluetooth/" || return 1
  install -D -m644 "$srcdir/$pkgname-$pkgver/audio/audio.conf"     "$pkgdir/etc/bluetooth/" || return 1
  install -D -m644 "$srcdir/bluetooth.conf.d"                     "$pkgdir/etc/conf.d/bluetooth" || return 1
  install -D -m755 "$srcdir/run.bluetoothd"                       "$pkgdir/etc/sv/bluetoothd/run" || return 1
  install -D -m755 "$srcdir/run.hidd"                             "$pkgdir/etc/sv/hidd/run" || return 1
  install -D -m755 "$srcdir/run.dund"                             "$pkgdir/etc/sv/dund/run" || return 1
  install -D -m755 "$srcdir/run.pand"                             "$pkgdir/etc/sv/pand/run" || return 1
  install -D -m755 "$srcdir/run.rfcomm"                           "$pkgdir/etc/sv/rfcomm/run" || return 1
}
md5sums=('350568aa11a95eac6e56e9289ff1f91d'
         'd12be5b494525bb1ba6eac5c3983dd3e'
         '1c88fcd455920ad8ee0c7cae3fe15771'
         'a9c1b4da8b5a3969865272bd0fb01da2'
         '89c073f43a074844b87e28103e48623d'
         '8ee99afea417561d01012b8047fd06d5'
         '934a9eaa25c275d18115068101fb75e8')