# Maintainer: Geoffroy Carrier <geoffroy@archlinux.org>
pkgname=bluez
pkgver=4.62
pkgrel=2
pkgdesc="Libraries and tools for the Bluetooth protocol stack"
url="http://www.bluez.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus-core' 'glib2')
makedepends=('gstreamer0.10-base' 'alsa-lib' 'libusb')
optdepends=('gstreamer0.10-base' 'alsa-lib' 'libusb')
conflicts=('bluez-libs' 'bluez-utils')
provides=('bluez-libs' 'bluez-utils')
replaces=('bluez-libs' 'bluez-utils')
install='bluez.install'
backup=(etc/bluetooth/{main,rfcomm,audio,network,input}.conf
        etc/conf.d/bluetooth)
source=("http://www.kernel.org/pub/linux/bluetooth/$pkgname-$pkgver.tar.bz2"
        bluetooth.conf.d run.bluetoothd run.sdpd run.hidd run.dund run.pand
        run.rfcomm run.hid2hci)

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr \
        --sysconfdir=/etc \
        --localstatedir=/var \
        --libexecdir=/lib \
        --mandir=/usr/share/man \
        --enable-gstreamer \
        --enable-alsa \
        --enable-usb \
        --enable-netlink \
        --enable-tools \
        --enable-bccmd \
        --enable-hid2hci \
        --enable-dfutool \
        --enable-hidd \
        --enable-pand \
        --enable-dund \
        --enable-cups \
        --enable-manpages \
        --enable-configfiles \
        --enable-pcmciarules || return 1
  make || return 1
  make DESTDIR="$pkgdir" install || return 1

  install -D -m644 "$srcdir/$pkgname-$pkgver/network/network.conf" "$pkgdir/etc/bluetooth/" || return 1
  install -D -m644 "$srcdir/$pkgname-$pkgver/input/input.conf"     "$pkgdir/etc/bluetooth/" || return 1
  install -D -m644 "$srcdir/$pkgname-$pkgver/audio/audio.conf"     "$pkgdir/etc/bluetooth/" || return 1
  install -D -m644 "$srcdir/bluetooth.conf.d"                     "$pkgdir/etc/conf.d/bluetooth" || return 1
  install -D -m755 "$srcdir/run.bluetoothd"                       "$pkgdir/etc/sv/bluetoothd/run" || return 1
  install -D -m755 "$srcdir/run.sdpd"                             "$pkgdir/etc/sv/sdpd/run" || return 1
  install -D -m755 "$srcdir/run.hidd"                             "$pkgdir/etc/sv/hidd/run" || return 1
  install -D -m755 "$srcdir/run.dund"                             "$pkgdir/etc/sv/dund/run" || return 1
  install -D -m755 "$srcdir/run.pand"                             "$pkgdir/etc/sv/pand/run" || return 1
  install -D -m755 "$srcdir/run.rfcomm"                           "$pkgdir/etc/sv/rfcomm/run" || return 1
  install -D -m755 "$srcdir/run.hid2hci"                          "$pkgdir/etc/sv/hid2hci/run" || return 1
}
md5sums=('3c2187a97f5b43ae84b4bbd4b34671e0'
         'd12be5b494525bb1ba6eac5c3983dd3e'
         '1c88fcd455920ad8ee0c7cae3fe15771'
         'fc8cdfd1fb0044a674b79c41d5d88388'
         '2483128d1cb93aeaf15d66058c052dc2'
         '95bfe0ff91559d719e5feecb0388b4e1'
         'b130f90a3cab7dd8a40c558d95c540a2'
         'a416cdf7cc7c954f6b09d6c2a1d1c0d3'
         'dd046ee5a232ba7cdbe8006d90b479e5')