# Contributer: Sebastian Sareyko <public@nooms.de>

pkgname=projectx
pkgver=0.90.4.00
pkgrel=7
license=('GPL')
arch=('i686' 'x86_64')
pkgdesc="DVB demux tool for repairing and analyzing different stream types"
makedepends=('jdk')
depends=('jre')
url="http://sourceforge.net/projects/project-x"
source=(http://dl.sourceforge.net/sourceforge/project-x/ProjectX_Source_eng_$pkgver.zip \
	http://dl.sourceforge.net/sourceforge/project-x/ProjectX_LanguagePack_$pkgver.zip \
	projectx)
md5sums=('92d7b5aea50b8811307f27b6e01ceb5c'
         'edfe8d04bd3d403eec4d9e27d1b976d2'
         '60c3056d1051eb174ec63a4039ad40ff')

build() {
    cd $startdir/src/ProjectX_Source_0.90.4

    sed -i 's,^Exec=.*,Exec=projectx,' projectx.desktop
    
    if [ -z "$J2SDKDIR" ] ; then
        . /etc/profile.d/jdk.sh
    fi

    mkdir -p build

    javac -encoding "ISO-8859-1" -O -g:none \
        -classpath lib/commons-net-1.3.0.jar:lib/jakarta-oro-2.0.8.jar \
        -d build @sources.lst || return 1

    cp resources/* ./build
    jar cvfm ProjectX.jar MANIFEST.MF -C build .

    install -D -m0755 $startdir/projectx $startdir/pkg/usr/bin/projectx
    install -D -m0644 ProjectX.jar $startdir/pkg/opt/projectx/ProjectX.jar
    install -D -m0644 lib/commons-net-1.3.0.jar \
        $startdir/pkg/opt/projectx/lib/commons-net-1.3.0.jar
    install -D -m0644 lib/jakarta-oro-2.0.8.jar \
        $startdir/pkg/opt/projectx/lib/jakarta-oro-2.0.8.jar
    install -D -m0644 projectx.desktop $startdir/pkg/usr/share/applications/projectx.desktop
    for file in ReadMe.txt ReleaseNotes_0.90.4.00.txt ReleaseNotes_0.90.4.txt $( find htmls -type f ) ; 
    do
        install -D $file $startdir/pkg/opt/projectx/$file
    done

}