# $Id: PKGBUILD 29213 2009-03-06 18:47:56Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-screensaver
pkgver=2.24.1
pkgrel=7
pkgdesc="Screensaver designed to integrate well with the GNOME desktop."
arch=(i686 x86_64)
license=('GPL')
url="http://live.gnome.org/GnomeScreensaver"
backup=(etc/pam.d/gnome-screensaver)
depends=('gnome-menus>=2.24.2' 'libgnomekbd>=2.24.0' 'libxss' 'libgl' 'libnotify' 'gnome-desktop>=2.24.2' 'libxxf86misc')
makedepends=('pkgconfig' 'gettext' 'intltool' 'mesa' 'xscreensaver' 'libxslt')
groups=('gnome')
options=(!emptydirs)
install=gnome-screensaver.install
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/2.24/${pkgname}-${pkgver}.tar.bz2
	gnome-screensaver.pam
	bug564548.patch)
md5sums=('f0b9cc3108bb9105141a8c22b56bf615'
         '4b4d2672a787e0d2ed792b4c308ccf8d'
	 'b2accd56fd1e7e3855c1cee3cc3780c4')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i "${srcdir}/bug564548.patch" || return 1
  ./configure --prefix=/usr --sysconfdir=/etc \
              --libexecdir=/usr/lib/gnome-screensaver \
              --localstatedir=/var --with-gdm-config=/usr/share/gdm/defaults.conf \
	      --with-xscreensaverdir=/usr/share/xscreensaver/config \
	      --with-xscreensaverhackdir=/usr/lib/xscreensaver \
	      --with-dpms-ext || return 1
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1

  install -m644 "${srcdir}/gnome-screensaver.pam" "${pkgdir}/etc/pam.d/gnome-screensaver" || return 1

  #Migrate xscreensaver configuration files
  cd "${pkgdir}/usr/share/applications/screensavers"
  "${srcdir}/${pkgname}-${pkgver}/data/migrate-xscreensaver-config.sh" /usr/share/xscreensaver/config/*.xml || return 1
  
  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" ${pkgdir}/etc/gconf/schemas/*.schemas || return 1
  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
  ls $pkgdir/usr/share/applications/screensavers/|cut -d. -f1 > $startdir/gscreensavers

}