# $Id: PKGBUILD 75323 2010-04-01 10:16:24Z allan $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Manolis Tzanidakis

pkgname=autofs
pkgver=5.0.5
pkgrel=1
pkgdesc="A kernel-based automounter for Linux"
arch=('i686' 'x86_64')
url="http://wiki.autofs.net/FrontPage"
license=('GPL2')
depends=('libldap' 'libxml2' 'heimdal')
backup=(etc/autofs/auto.master etc/autofs/auto.misc etc/conf.d/autofs)
install=${pkgname}.install
source=("http://www.kernel.org/pub/linux/daemons/${pkgname}/v5/${pkgname}-${pkgver}.tar.bz2"
  'autofs.conf.d' 'auto.master' 'auto.misc'
  'heimdal.patch' 'run' 'log.run' 'finish')

build() {
  export MAKEFLAGS="-j1"
  cd ${srcdir}/${pkgname}-${pkgver}

  sed -i "s:SUBDIRS = lib daemon modules man samples:SUBDIRS = lib daemon modules man:" Makefile.rules
  patch -Np1 -i ${srcdir}/heimdal.patch

  ./configure --prefix=/usr \
    --sysconfdir=/etc/autofs \
    --with-mapdir=/etc/autofs \
    --without-hesiod
  make || return 1

  sed -i "s:/etc:/etc/autofs:g" man/auto.master.5
}

package(){
  cd ${srcdir}/${pkgname}-${pkgver}
  make INSTALLROOT=${pkgdir} install
  
  install -Dm644 ${srcdir}/auto.master ${pkgdir}/etc/autofs/auto.master || return 1
  install -Dm644 ${srcdir}/auto.misc ${pkgdir}/etc/autofs/auto.misc || return 1
  install -Dm644 ${srcdir}/autofs.conf.d ${pkgdir}/etc/conf.d/autofs || return 1
  mkdir -p ${pkgdir}/etc/sv/autofs/supervise
  mkdir -p ${pkgdir}/etc/sv/autofs/log/supervise
  install -Dm744 ${srcdir}/run ${pkgdir}/etc/sv/autofs || return 1
  install -Dm744 ${srcdir}/finish ${pkgdir}/etc/sv/autofs || return 1
  install -Dm744 ${srcdir}/log.run ${pkgdir}/etc/sv/autofs/log/run || return 1
}

md5sums=('a1d262cb6ebef0c2dd0fe22232fb3d5a'
         '47f597c870410055e0fdb66103daf928'
         'a6cefb591e77b31b79dbb7243646c96b'
         'd8a15ec9186c5c0b36e5cea1e2739e8a'
         'efd46b6406b940cb48f7c6197790fb8e'
         'f2048c24da7fa1421c2e8b0b90fb17f9'
         '518e277f960a1af837ba6c5cca13c615'
         '5b30948886b6d71287652d784fccf1fb')