# Maintainer: Geoffroy Carrier <geoffroy@archlinux.org>
pkgname=bluez
pkgver=4.99
pkgrel=3
pkgdesc="Libraries and tools for the Bluetooth protocol stack"
url="http://www.bluez.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus-core')
makedepends=('gstreamer0.10-base' 'libusb-compat' 'libnl' 'libsndfile')
optdepends=("gstreamer0.10-base: bluetooth GStreamer support"
	"alsa-lib: Audio bluetooth devices support"
	"dbus-python: to run bluez-simple-agent"
	"pygobject: to run bluez-simple-agent"
	"libusb-compat: USB adapters support"
	"libnl: netlink plugin")
conflicts=('bluez-libs' 'bluez-utils')
provides=('bluez-libs' 'bluez-utils')
replaces=('bluez-libs' 'bluez-utils')
options=('!libtool')
backup=(etc/bluetooth/{main,rfcomm,audio,network,input,serial}.conf
        'etc/conf.d/bluetooth' 'etc/dbus-1/system.d/bluetooth.conf')
install='bluez.install'
source=("http://www.kernel.org/pub/linux/bluetooth/$pkgname-$pkgver.tar.bz2"
        'bluez-4.98_audio-streaming.patch'
        'bluetooth.conf.d')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # Add directive that allows audio streaming out-of-the-box
  patch -Np1 -i ${srcdir}/bluez-4.98_audio-streaming.patch || return 1

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --libexecdir=/lib \
    --enable-gstreamer \
    --enable-alsa \
    --enable-usb \
    --enable-tools \
    --enable-bccmd \
    --enable-dfutool \
    --enable-hidd \
    --enable-pand \
    --enable-dund \
    --enable-wiimote \
    --disable-test \
    --disable-cups || return 1

  make || return 1
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install || return 1

  install -d ${pkgdir}/etc/bluetooth
  install -m644 network/network.conf \
                input/input.conf \
                audio/audio.conf \
                serial/serial.conf \
    ${pkgdir}/etc/bluetooth/

  install -D -m644 "$srcdir/bluetooth.conf.d" \
                   "$pkgdir/etc/conf.d/bluetooth" || return 1
  
  install -Dm755 test/simple-agent ${pkgdir}/usr/bin/bluez-simple-agent
  install -Dm755 test/test-device "${pkgdir}"/usr/bin/bluez-test-device
  install -Dm755 test/test-input "${pkgdir}"/usr/bin/bluez-test-input
  sed -i 's#/usr/bin/python#/usr/bin/python2#' \
         ${pkgdir}/usr/bin/bluez-simple-agent \
         ${pkgdir}/usr/bin/bluez-test-device \
         ${pkgdir}/usr/bin/bluez-test-input
}
md5sums=('2387053eb5a7b02f37df4871df022a02'
         'da4ec22ee1a5c3e84d5d934440167526'
         'd12be5b494525bb1ba6eac5c3983dd3e')