# $Id: PKGBUILD 23076 2009-01-02 11:33:41Z alexanderf $
# Maintainer: Alexander Fehr <pizzapunk gmail com>
# Contributor: Alessio 'mOLOk' Bolognino <themolok@gmail.com>

pkgname=transmission-cli
pkgver=2.51
pkgrel=1
pkgdesc="Fast, easy, and free BitTorrent client (CLI tools, daemon and web client)"
arch=('i686' 'x86_64')
url="http://www.transmissionbt.com/"
license=('MIT')
depends=('curl' 'libevent>=2.0.10')
makedepends=('intltool' 'libcroco')
replaces=('transmission')
backup=('etc/conf.d/transmissiond')
install=transmission-cli.install
source=(http://mirrors.m0k.org/transmission/files/transmission-$pkgver.tar.bz2
        run.transmissiond
        transmission-cli.install
        transmission.include
        transmissiond.conf)

build() {
  cd "$srcdir/transmission-$pkgver"

  ./configure --prefix=/usr --disable-gtk || return 1
  make || return 1
}

package() {
  cd "$srcdir/transmission-$pkgver"
  make DESTDIR="$pkgdir" install || return 1

  mkdir -p -m744 "$pkgdir/etc/sv/transmissiond" || return 1
  mkdir -p -m777 "$pkgdir/myth/transmission" || return 1
  install -D -m755 "$srcdir/run.transmissiond" "$pkgdir/etc/sv/transmissiond/run" || return 1
  install -D -m644 "$srcdir/transmissiond.conf" "$pkgdir/etc/conf.d/transmissiond" || return 1
  install -D -m644 "$srcdir/transmission.include" "$pkgdir/etc/transmission/transmission.include" || return 1
  install -D -m644 COPYING "$pkgdir/usr/share/licenses/transmission-cli/COPYING" || return 1
}
md5sums=('dfe2faeb2b76b43954ec943affef2133'
         'e876d24b99c401f782395b053976dffd'
         'ff22c13dbd52565f9e88b1de22514eb9'
         'b5a49ea375333cd0fee40f70dbac4c2e'
         'd05567c7a4f9df9f28602d1356d5c05c')