# $Id: PKGBUILD 72807 2010-03-20 04:06:14Z allan $
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=guile
pkgver=1.8.7
pkgrel=2
pkgdesc="Guile is a portable, embeddable Scheme implementation written in C"
url="http://www.gnu.org/software/guile/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gmp' 'libtool' 'ncurses>=5.7' 'texinfo')
install=guile.install
source=(ftp://ftp.gnu.org/pub/gnu/${pkgname}/${pkgname}-${pkgver}.tar.gz
        guile-snarf.patch)
options=('!libtool' '!makeflags')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # Fix build failure without -P
  # http://old.nabble.com/build-failure-just-trying-to-build-guile-1.8.7-natively-td26411839.html
  patch -Np1 < ${srcdir}/guile-snarf.patch || return 1

  ./configure --prefix=/usr --disable-error-on-warning || return 1
  make LDFLAGS+="-lpthread" || return 1
}
package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install || return 1
  rm -f "${pkgdir}/usr/share/info/dir"
  gzip "${pkgdir}/usr/share/info"/* || return 1
}
md5sums=('991b5b3efcbbc3f7507d05bc42f80a5e'
         'c11264d2a80858ab2ea1af761a6f6e65')