# Maintainer: BlackEagle <ike DOT devolder AT gmail DOT com>
# Contributor: Bernhard Walle <bernhard.walle@gmx.de>
pkgname=lcdproc
pkgver=0.5.6
pkgrel=1
pkgdesc="Utility to drive one or more LCD (and LCD-like) devices"
url="http://lcdproc.omnipotent.net/"
license="GPL"
depends=('libusb-compat')
optdepends=(
	'perl: needed for some lcdproc tools'
)
backup=(
	'etc/LCDd.conf'
	'etc/lcdexec.conf'
	'etc/lcdproc.conf'
	'etc/lcdvc.conf'
)
arch=('i686' 'x86_64')
source=(
	"http://switch.dl.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver-pre1.tar.gz"
	'lcdd'
)

build() {
	cd "$pkgname-$pkgver-pre1"
	./configure \
		--prefix=/usr \
		--sysconfdir=/etc \
		--enable-libusb \
		--enable-lcdproc-menus \
		--enable-stat-smbfs \
		--enable-drivers=all
	make
}

package() {
	cd "$pkgname-$pkgver-pre1"
	make DESTDIR="$pkgdir" install
	sed -e "s/server\/drivers\//\/usr\/lib\/lcdproc\//g" -i "$pkgdir/etc/LCDd.conf"
	install -Dm755 "$srcdir/lcdd" "$pkgdir/etc/rc.d/lcdd"
}
md5sums=('2175376ebefc18280b494e5f0a68329b'
         '56f52dcccd6e129a9cf84cd1a0452d56')