# Maintainer: Jeff Keyte <jeff@keyte.me>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Daniel Wallace <daniel.wallace@gatech.edu>

pkgname=openpht
pkgver=1.8.0.148
_pkghash=573b6d73
pkgrel=3
pkgdesc='OpenPHT is a community driven fork of Plex Home Theater'
arch=('i686' 'x86_64')
url='https://github.com/RasPlex/OpenPHT/'
license=('GPL2')
install="${pkgname}.install"
provides=('plex-home-theater')
#conflicts=('plex-home-theater')
replaces=('plex-home-theater')
depends=('alsa-lib' 'avahi' 'boost-libs' 'curl' 'expat' 'ffmpeg2.8' 'freetype2' 'fribidi'
         'gcc-libs' 'glew' 'glibc' 'glu' 'libcdio' 'libgl' 'libjpeg' 'libmad'
         'libmicrohttpd' 'libmpeg2' 'libpng' 'libsamplerate' 'llvm-libs'
         'libssh' 'libtiff' 'libusb-compat' 'libva' 'libvdpau' 'libx11'
         'libxext' 'libxrandr' 'lzo' 'pcre' 'python2' 'sdl' 'sdl_image'
         'sdl_mixer' 'sqlite' 'smbclient' 'taglib' 'tinyxml' 'yajl' 'zlib' 'rtmpdump')
makedepends=('boost' 'cmake' 'doxygen' 'git' 'java-environment' 'shairplay'
             'libplist' 'nasm' 'swig' 'unzip' 'zip' 'gcc-libs' 'glibc' 'llvm-libs')
optdepends=('libplist: AirPlay support'
            'libcec: Pulse-Eight USB-CEC adapter support'
            'shairplay: Shairplay Support')
source=("https://github.com/RasPlex/OpenPHT/archive/v${pkgver}-${_pkghash}.tar.gz"
        'plex_lib.conf'
        'fribidi.patch'
        'websocketSSL.patch'
        'plexNetwork.patch'
        'plexhometheater.desktop')

prepare() {
  cd OpenPHT-${pkgver}-${_pkghash}
  patch -Np1 <../fribidi.patch
  patch -Np2 <../plexNetwork.patch
  patch -Np1 <../websocketSSL.patch
}

build() {
  cd OpenPHT-${pkgver}-${_pkghash}

  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build && cd build

  CMAKE_PREFIX_PATH=/usr/lib/ffmpeg2.8:/usr/include/ffmpeg2.8 \
  cmake .. \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DENABLE_AUTOUPDATE='FALSE' \
    -DENABLE_PYTHON='TRUE' \
    -DPYTHON_EXEC='/usr/bin/python2' \
    -DUSE_INTERNAL_FFMPEG='FALSE' \
    -DENABLE_CEC:BOOL='FALSE'
  make
}

package() {
  cd OpenPHT-${pkgver}-${_pkghash}/build

  make DESTDIR="${pkgdir}" install

  # LinHES stuff
  # add in plex_lib.conf
  install -D -m0744 ${srcdir}/plex_lib.conf ${pkgdir}/etc/gen_lib_xml.d/plex_lib.conf
}
md5sums=('7eddac9c7638d70c2a25d04cc451ddcc'
         'b9524fe29d0cc65087ba447d1b892da2'
         'a5980579c1b6341a6d06e80d9da2a924'
         'ed2262e0991a4f28483542abc05d8d90'
         'b4abf25d4da8e4f8e8722a9233fe7fc1'
         'e530e2b4d8333863ba1c87862c291ba1')