# $Id: PKGBUILD 70372 2010-02-26 13:35:23Z paul $
# Contributor: Jeff Brodnax <tullyarcher@bellsouth.net>
# Maintainer: Paul Mattal <paul@archlinux.org>
pkgname=postfix
pkgver=2.7.0
pkgrel=1
pkgdesc="Secure, fast, easy to administer drop in replacement for Sendmail (MTA)"
arch=('i686' 'x86_64')
license=('custom')
depends=('pcre' 'libsasl'   'db>=4.7')
backup=(etc/postfix/aliases etc/postfix/virtual etc/postfix/relocated \
	etc/postfix/access etc/postfix/header_checks etc/postfix/transport \
	etc/postfix/generic etc/postfix/canonical \
	etc/postfix/main.cf etc/postfix/master.cf)
install="${pkgname}.install"
provides=('smtp-server' 'smtp-forwarder')
replaces=('postfix-mysql' 'postfix-pgsql')
conflicts=('postfix-mysql' 'postfix-pgsql' 'smtp-server' 'smtp-forwarder')
url="http://www.postfix.org/"
source=(ftp://ftp.porcupine.org/mirrors/postfix-release/official/${pkgname}-${pkgver}.tar.gz \
        ${pkgname}.patch.bz2 \
	${pkgname})
md5sums=('df648f59421604e895cce56325f00bae'
         'a3c45ff23ef036143711793fcf2478c3'
         'c847b96f08925f08b0f610468a8e21f6')

build() {
	cd ${srcdir}/${pkgname}-${pkgver}
	
	make makefiles \
	        CCARGS="-DUSE_SASL_AUTH -I/usr/include/sasl \
			-DUSE_CYRUS_SASL \
			-DUSE_TLS" \
	        AUXLIBS="-lsasl2 -lssl -lcrypto  -llber -lz -lm "
	make OPT="${CFLAGS}" || return 1

	sh postfix-install -non-interactive \
		install_root="${pkgdir}" \
		daemon_directory="/usr/lib/${pkgname}" \
		sample_directory="/etc/${pkgname}/sample" \
		manpage_directory="/usr/share/man"

	cd ${pkgdir}
	cat ${srcdir}/${pkgname}.patch |patch -Np0 || return 1
	rm -f etc/${pkgname}/main.cf~

	cd ${pkgdir}
	mkdir etc/rc.d
	install -m 0755 ${srcdir}/${pkgname} etc/rc.d/${pkgname}

	install -Dm644 ${srcdir}/${pkgname}-${pkgver}/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}