pkgname=shellinabox
pkgver=2.20
pkgrel=1
_pkghash=master
pkgdesc="Implementation of a web server that can export arbitrary command line tools to a web based terminal emulator"
arch=('i686' 'x86_64')
url="http://shellinabox.com/"
license=('GPL2')
depends=('runit-scripts>=8.0-2' 'openssh')
install=shellinaboxd.install
source=("https://github.com/shellinabox/shellinabox/archive/${_pkghash}.tar.gz"
        "shellinaboxd.include"
        "shellinaboxd.gen_light_conf.d")

build() {
  cd "$srcdir/$pkgname-${_pkghash}"

  #change default to show onscreen keyboard
  sed -i "s/this.softKeyboard         = false;/this.softKeyboard         = true;/g" ./shellinabox/vt100.jspp

  #fix unsupported option errors with openssh
  find . -name "service.c" -exec sed -i -e "s|-oRhostsRSAAuthentication=no||g" {} \;
  find . -name "service.c" -exec sed -i -e "s|-oRSAAuthentication=no||g" {} \; 

  autoreconf -i
  export CPPFLAGS="${CPPFLAGS/-D_FORTIFY_SOURCE=2/}"
  ./configure  --prefix=/usr

  #fix ssl libs
  sed -i -e "s|LIBS = -lz -ldl -lutil|LIBS = -lz -ldl -lutil -lssl -lcrypto|g" ./Makefile

  make
}
package() {
  cd "$srcdir/$pkgname-${_pkghash}"
  make DESTDIR=$pkgdir install || return 1

  #install conf files for lighttpd
  mkdir -p ${pkgdir}/etc/lighttpd
  install -D -m 644 ${srcdir}/shellinaboxd.include ${pkgdir}/etc/lighttpd/
  #gen_light_conf
  install -D -m 744 ${srcdir}/shellinaboxd.gen_light_conf.d ${pkgdir}/etc/gen_light_conf.d/shellinaboxd.conf
}
md5sums=('20e8876ce8637ebf4fc98b1e7807bed9'
         '4c5ce3c17bed94ca71ebafba7f934bba'
         'aadd1edf4110aca2d16d806791e90019')