# $Id: PKGBUILD 161432 2012-06-11 13:29:15Z tpowa $
#Maintainer: Tobias Powalowski <tpowa@archlinux.org>

pkgname=unison
pkgver=2.32.52
pkgrel=1
pkgdesc="Unison is a file-synchronization tool"
arch=(i686 x86_64)
license=('GPL2')
url="http://www.cis.upenn.edu/~bcpierce/unison"
depends=('glibc')
makedepends=('ocaml' 'lablgtk2' 'imagemagick')
optdepends=('gtk2: for gtk2 support')
#http://www.cis.upenn.edu/~bcpierce/unison/download/releases/unison-2.32.52/unison-2.32.52.tar.gz
source=(http://www.cis.upenn.edu/~bcpierce/unison/download/releases/$pkgname-$pkgver/$pkgname-$pkgver.tar.gz
        $pkgname.desktop unison-ssh-ocaml.patch)
options=(!makeflags)

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -p1 < $srcdir/unison-ssh-ocaml.patch
  CFLAGS=""
  make clean
  make mkProjectInfo 
  make UISTYLE=text DEBUGGING=false THREADS=true 
  mv unison unison-text
 
 # clean the builddir and rebuild with gtk support
  # broken at the moment!
  # make clean
  # make mkProjectInfo
  # make UISTYLE=gtk DEBUGGING=false THREADS=true
  # install -Dm755 unison "$pkgdir"/usr/bin/unison-gtk
 # clean the builddir and rebuild with gtk2 support
  make clean
  make mkProjectInfo
  make UISTYLE=gtk2 DEBUGGING=false THREADS=true
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -Dm755 unison-text "$pkgdir"/usr/bin/unison
  install -Dm755 unison "$pkgdir"/usr/bin/unison-gtk2
 # install a .desktop file; create a compliant icon from ico file and install the png
  install -Dm644 ../$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
  convert win32rc/U.ico unison.png
  install -Dm644 ${pkgname}-1.png  "$pkgdir"/usr/share/pixmaps/$pkgname.png
 # make symlink for .desktop file
  cd "$pkgdir"/usr/bin
  ln -s unison-gtk2 unison-x11
 # make versioned symlink #29827
  ln -s unison unison-2.40
}
md5sums=('0701f095c1721776a0454b94607eda48'
         '2daecba7705455a8e4b769e48b059872'
         '81a28349471434c75a4206d07ad21eb1')