# $Id: PKGBUILD 99629 2010-11-15 21:53:38Z eric $
# Maintainer: Eric Belanger <eric@archlinux.org>

pkgname=wxgtk
pkgver=2.8.11
pkgrel=2
pkgdesc="GTK+ implementation of wxWidgets API for GUI"
arch=('i686' 'x86_64')
url="http://wxwidgets.org"
license=('custom:wxWindows')
depends=('gtk2' 'gstreamer0.10-base' 'libgl' 'libxxf86vm')
makedepends=('gstreamer0.10-base-plugins' 'gconf' 'mesa')
#source=(http://downloads.sourceforge.net/wxpython/wxPython-src-${pkgver}.tar.bz2)
source=(http://downloads.sourceforge.net/wxwindows/wxGTK-${pkgver}.tar.bz2)
md5sums=('6040933d200037f90f6aa1c5169e7ec6')
sha1sums=('e979d9d2b1ee5bd10e90fd00b02f3306327c661a')

build() {
#  cd "${srcdir}/wxPython-src-${pkgver}"
  cd "${srcdir}/wxGTK-${pkgver}"
  ./configure --prefix=/usr --libdir=/usr/lib --with-gtk=2 --with-opengl --enable-unicode \
    --enable-graphics_ctx --disable-optimize --enable-mediactrl \
    --with-libpng=sys --with-libxpm=sys --with-libjpeg=sys --with-libtiff=sys
  make
  make -C locale allmo
  cd contrib/src
  make
}

package() {
  cd "${srcdir}/wxGTK-${pkgver}"
  make DESTDIR="${pkgdir}" install
  cd contrib/src
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../../docs/licence.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}