AC_PREREQ(2.54)

AC_INIT(ghosd, 0.0.1, [martine@danga.com])
AC_CONFIG_SRCDIR(ghosd/ghosd.c)
AC_CONFIG_HEADERS(config.h)
AM_INIT_AUTOMAKE([1.7])

# libtool versioning information.
# we're gonna break this API regularly until the first release, though.
LT_CURRENT=0
LT_REVISION=0
LT_AGE=0

VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
AC_SUBST(VERSION_INFO)

AM_MAINTAINER_MODE

AC_PROG_CC
AC_PROG_LIBTOOL

WARN_CFLAGS=""
if test "x$GCC" = "xyes"; then
	WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
               -Wmissing-prototypes -Wmissing-declarations \
               -Wnested-externs -fno-strict-aliasing"
fi

CFLAGS="$CFLAGS $WARN_CFLAGS"

GHOSD_PACKAGES="cairo"
AC_ARG_ENABLE(pango,
              [AC_HELP_STRING(--enable-pango, [use pango (default on)])],
              , [enable_pango=yes])
if test "$enable_pango" = "yes"; then
  GHOSD_PACKAGES="$GHOSD_PACKAGES pangocairo"
  AC_DEFINE([HAVE_PANGO], [], [we have pangocairo])
fi
AM_CONDITIONAL([PANGO], test "$enable_pango" = "yes")

PKG_CHECK_MODULES([GHOSD], $GHOSD_PACKAGES)
AC_SUBST(GHOSD_PACKAGES)
AC_SUBST(GHOSD_CFLAGS)
AC_SUBST(GHOSD_LIBS)

PKG_CHECK_MODULES([GHOSD_EXAMPLE], $GHOSD_PACKAGES glib-2.0 >= 2.6)
AC_SUBST(GHOSD_EXAMPLE_CFLAGS)
AC_SUBST(GHOSD_EXAMPLE_LIBS)

GTK_DOC_CHECK(1.3)

AC_OUTPUT([
Makefile
ghosd.pc
ghosd/Makefile
examples/Makefile
doc/Makefile
])

# vim: set ts=2 sw=2 et cino=(0 :