# Contributor: James Rayner <iphitus@gmail.com>

pkgname=tiacx
pkgver=20080210
pkgrel=22
pkgdesc="OpenSource module for Texas Instruments ACX100/ACX111 wireless chips. For stock arch 2.6 kernel"
arch=(i686 x86_64)
url="http://acx100.sourceforge.net/"
license=('MPL')
depends=('wireless_tools' 'kernel26>=2.6.39' 'kernel26<2.6.40' 'tiacx-firmware')
makedepends=('kernel26-headers>=2.6.39' 'kernel26-headers<2.6.40')
install=acx.install
source=(http://downloads.sourceforge.net/sourceforge/acx100/acx-$pkgver.tar.bz2
        kernel-2.6.27.patch
        kernel-2.6.30.patch
        kernel-2.6.31.patch
        kernel-2.6.33.patch)
options=(!strip)
_kernver=2.6.39-LinHES
md5sums=('7d5ce3215708e4e9f95cf567a9ee3a12'
         '9895f72f8d0c84956b0f6c3b16df0fe8'
         'e2900aee839ce711a7f7606b3e3de36e'
         'dbcb276d77df7801cef58a85c18dfe94'
         '9cd35ea33b8abdd2e4efec485b05477e')

build() {
    cd $srcdir/acx-$pkgver
    patch -Np1 -i ../kernel-2.6.27.patch 
    patch -Np0 -i ../kernel-2.6.30.patch
    patch -Np1 -i ../kernel-2.6.31.patch
    patch -Np0 -i ../kernel-2.6.33.patch
    make -C /lib/modules/${_kernver}/build M=$(pwd)
}

package () {
    cd $srcdir/acx-$pkgver
    install -D acx.ko $pkgdir/lib/modules/${_kernver}/kernel/drivers/net/wireless/tiacx/acx.ko
    sed -i -e "s/KERNEL_VERSION='.*'/KERNEL_VERSION='${_kernver}'/" $startdir/*.install
    # gzip -9 modules
    find "$pkgdir" -name '*.ko' -exec gzip -9 {} \;
}