# $Id: PKGBUILD 96495 2010-10-21 21:13:19Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=xorg-utils
pkgver=7.6
pkgrel=6
pkgdesc="Collection of client utilities used to query the X server"
arch=('i686' 'x86_64')
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('libxxf86dga' 'libxi' 'libxtst' 'libxinerama' 'libxv'
         'libdmx' 'libxft' 'libxaw>=1.0.6' 'libgl' 'libxcomposite' 'xcb-util')
makedepends=('pkgconfig' 'mesa' 'glproto' 'xorg-util-macros')
groups=('xorg')
source=(${url}/releases/individual/app/xdpyinfo-1.2.0.tar.bz2
        ${url}/releases/individual/app/xdriinfo-1.0.3.tar.bz2
        ${url}/releases/individual/app/xev-1.0.4.tar.bz2
        ${url}/releases/individual/app/xfd-1.1.0.tar.bz2
        ${url}/releases/individual/app/xfontsel-1.0.3.tar.bz2
        ${url}/releases/individual/app/xlsatoms-1.1.0.tar.bz2
        ${url}/releases/individual/app/xlsclients-1.1.1.tar.bz2
        ${url}/releases/individual/app/xlsfonts-1.0.3.tar.bz2
        ${url}/releases/individual/app/xprop-1.1.0.tar.bz2
        ${url}/releases/individual/app/xvinfo-1.1.0.tar.bz2
        ${url}/releases/individual/app/xwininfo-1.1.0.tar.bz2
        LICENSE.xprop
        LICENSE.xlsfonts)
md5sums=('c52fda7bbc80e74b7839f29298cb1d77'
         'cb304d1ce562ac48b68eedeba38c662f'
         '5f98c0a2725a33d60ef4956befe078fb'
         '17d8ef0d490301158f8abf7641cca243'
         '299fabe7d7be92b6572d814895ce3bb1'
         'c543ccb6489b629d427810d9a57d0724'
         '6d42621616da0c720f640d23873604ce'
         'bf6f3e7074479839d5182ffed735d2be'
         'f0bacbd30f0dd1c1e9ccafe97687b7a4'
         '8cc299b2cb636b5f7fe672610789d3d4'
         '932cb1393dee3caaf26f3515f640d783'
         '801f9850b29dad506e995d011efe2914'
         '345d6e65d71fdde292cc27f93c15e4a1')

build() {
  cd "${srcdir}"
  for i in *; do
    if [ -d "${i}" ]; then
      pushd "${i}"
      ./configure --prefix=/usr --mandir=/usr/share/man --without-xprint || return 1
      make || return 1
      make DESTDIR="${pkgdir}" install || return 1
      install -D -m644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.${i%-*} || return 1
      popd
    fi
  done
# Replacing stub license files
  install -D -m644 "${srcdir}"/LICENSE.* "${pkgdir}/usr/share/licenses/${pkgname}/"  || return 1
}