blob: 4ce2874d7260556d63ded8c2c8ea13a75d863e4a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer: Pierre Schmitz <pierre@archlinux.de>
pkgname=apr-util
pkgver=1.6.1
pkgrel=2
pkgdesc="The Apache Portable Runtime"
arch=('x86_64')
url="http://apr.apache.org/"
depends=('apr' 'expat')
makedepends=('gdbm' 'libldap' 'unixodbc' 'openssl' 'nss' 'sqlite' 'libmariadbclient' 'db' 'postgresql-libs' 'python2')
optdepends=(
'gdbm: enable gdbm support'
'libldap: enable ldap support'
'unixodbc: enable odbc support'
'libmariadbclient: enable mysql/mariadb support'
'postgresql-libs: enable postgres support'
'db: enable berkley db support'
'sqlite: enable sqlite support'
'nss: enable nss crypto support'
'openssl: enable openssl crypto support'
)
license=('APACHE')
source=(https://www.apache.org/dist/apr/apr-util-${pkgver}.tar.bz2{,.asc}
disable_failing_test.patch # TODO: figure out why dbm test fails
buildconf_config.guess_sub_location.patch)
sha512sums=('40eff8a37c0634f7fdddd6ca5e596b38de15fd10767a34c30bbe49c632816e8f3e1e230678034f578dd5816a94f246fb5dfdf48d644829af13bf28de3225205d'
'SKIP'
'f3de06f845972e5fc85c0d01847bcd0cfbbdd5015798970c73e5ef1b2699c54118f00ba5b939d84bbdf748bd1a5088c1393289b1e62c005fa77878436c165802'
'd19024b8a19e46e85dd03e2c06afae13b527e56c0e2864e5b92652c8ed558f155647f50b9cfaddb6e919b5a60922970b1d9f6c7fc62cd5872b3d22e787f99c65')
validpgpkeys=('5B5181C2C0AB13E59DA3F7A3EC582EB639FF092C' # Jeff Trawick
'B1B96F45DFBDCCF974019235193F180AB55D9977' # William A. Rowe, Jr. <wrowe@rowe-clan.net>
'3CE3BAC2EB7BBC624D1D22D8F3B9D88CB87F79A9') # Nick Kew <niq@apache.org>
prepare() {
cd apr-util-$pkgver
patch -Np1 -i ../buildconf_config.guess_sub_location.patch
patch -Np1 -i ../disable_failing_test.patch
./buildconf --with-apr=`apr-1-config --srcdir`
}
build() {
cd "${srcdir}/apr-util-${pkgver}"
./configure --prefix=/usr --with-apr=/usr --with-ldap --with-crypto \
--with-gdbm=/usr --with-sqlite3=/usr --with-nss=/usr --with-odbc=/usr \
--with-berkeley-db=/usr --with-pgsql=/usr --with-mysql=/usr --with-oracle=/usr \
--with-openssl=/usr
make
}
check() {
cd "${srcdir}/apr-util-${pkgver}"
make -j1 check
}
package() {
cd "${srcdir}/apr-util-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
